SqlScripts/01_DD_ECM/Update/Added2Main_script/1.8.0.0.sql

UPDATE TBDD_BASECONFIG SET DB_VERSION = '1.8.0.0'
GO

--PROCEDURES
CREATE PROCEDURE [dbo].[PRDD_DELETE_USER](@pUSER_ID INT)
AS
BEGIN TRY
	-- COMMON
	IF OBJECT_ID(N'dbo.TBDD_USER_MODULES', N'U') IS NOT NULL 
		DELETE FROM TBDD_USER_MODULES WHERE USER_ID = @pUSER_ID
	IF OBJECT_ID(N'dbo.TBDD_CLIENT_USER', N'U') IS NOT NULL 
		DELETE FROM TBDD_CLIENT_USER WHERE USER_ID = @pUSER_ID
	IF OBJECT_ID(N'dbo.TBDD_GROUPS_USER', N'U') IS NOT NULL 
		DELETE FROM TBDD_GROUPS_USER WHERE USER_ID = @pUSER_ID
	IF OBJECT_ID(N'dbo.TBDD_VERSION_USER_UPDATE', N'U') IS NOT NULL 
		DELETE FROM TBDD_VERSION_USER_UPDATE WHERE USER_ID = @pUSER_ID
	IF OBJECT_ID(N'dbo.TBDD_VERSION_USER_UPDATE_PATH', N'U') IS NOT NULL 
		DELETE FROM TBDD_VERSION_USER_UPDATE_PATH WHERE USER_ID = @pUSER_ID
	IF OBJECT_ID(N'dbo.TBDD_USER_LOGIN_OUT', N'U') IS NOT NULL 
		DELETE FROM TBDD_USER_LOGIN_OUT WHERE USER_ID = @pUSER_ID
	IF OBJECT_ID(N'dbo.TBDD_USER_MODULE_LOG_IN', N'U') IS NOT NULL 
		DELETE FROM TBDD_USER_MODULE_LOG_IN WHERE USER_ID = @pUSER_ID	

	-- PROCESS MANAGER
	IF OBJECT_ID(N'dbo.TBPM_PROFILE_USER', N'U') IS NOT NULL 
		DELETE FROM TBPM_PROFILE_USER WHERE USER_ID = @pUSER_ID

	-- GLOBAL INDEXER
	IF OBJECT_ID(N'dbo.TBGI_FOLDERWATCH_USER', N'U') IS NOT NULL 
		DELETE FROM TBGI_FOLDERWATCH_USER WHERE USER_ID = @pUSER_ID

	-- CLIPBOARD WATCHER
	IF OBJECT_ID(N'dbo.TBCW_USER_PROFILE', N'U') IS NOT NULL 
		DELETE FROM TBCW_USER_PROFILE WHERE USER_ID = @pUSER_ID

	-- FINALLY
	DELETE FROM TBDD_USER WHERE GUID = @pUSER_ID

	RETURN 0
END TRY
BEGIN CATCH   
	PRINT 'FEHLER IN PROCEDURE: ' + CONVERT(VARCHAR(30),ERROR_PROCEDURE()) + ' - ZEILE: ' + CONVERT(VARCHAR(10),ERROR_LINE())
	+ ' - FEHLER-MESSAGE: ' 
    + CONVERT(VARCHAR(500),ERROR_MESSAGE())
	RETURN -1
END CATCH
GO

ALTER FUNCTION [dbo].[FNDD_CHECK_USER_MODULE] (@pUSERNAME VARCHAR(100), @pMODULE_SHORT_NAME VARCHAR(10),@pCLIENTID INTEGER)
RETURNS @Table TABLE 
    (SequentialOrder INT IDENTITY(1, 1),
	USER_ID INTEGER, 
	USER_PRENAME VARCHAR(50), 
	USER_SURNAME VARCHAR(50), 
	USER_SHORTNAME VARCHAR(50),
	USER_EMAIL VARCHAR(100), 
	USER_LANGUAGE VARCHAR(10),
	USER_DATE_FORMAT VARCHAR(10),
	USER_RIGHT_FILE_DEL BIT,
	MODULE_ACCESS BIT,
	IS_ADMIN BIT, 
	USERCOUNT_LOGGED_IN INTEGER,
	COMMENT VARCHAR(500))
AS
BEGIN
/*
This function checks all user-relevant relations an
*/
	DECLARE
		@RESULT					VARCHAR(500),
		@USER_ID				INTEGER,
		@USER_PRENAME			VARCHAR(50),
		@USER_SURNAME			VARCHAR(50),
		@USER_SHORTNAME			VARCHAR(50),
		@USER_EMAIL				VARCHAR(50),
		@USER_LANGUAGE			VARCHAR(10),
		@USER_DATE_FORMAT		VARCHAR(10),
		@IS_IN_MODULE			BIT,
		@IS_ADMIN				BIT,
		@USER_RIGHT_FILE_DEL	BIT,
		@USERCOUNT_LOGGED_IN	INTEGER,
		@MODULE_NAME			VARCHAR(100),
		@MODULE_GUID			INTEGER,
		@USER_GROUPNAME			VARCHAR(100),
		@ADMIN_GROUPNAME		VARCHAR(100)

	SET @USER_ID = 0
	SET @IS_ADMIN = 0
	SET @IS_IN_MODULE = 0
	SET @USERCOUNT_LOGGED_IN = 0
	SET @RESULT = ''
	IF @pMODULE_SHORT_NAME = 'PM'
		BEGIN
			SET @USER_GROUPNAME = 'PM_USER'
			SET @ADMIN_GROUPNAME = 'PM_ADMINS'
			SEt @USER_RIGHT_FILE_DEL = 0
		END
	ELSE IF @pMODULE_SHORT_NAME = 'CW'
		BEGIN
			SET @USER_GROUPNAME = 'CW_USER'
			SET @ADMIN_GROUPNAME = 'CW_ADMINS'
		END
	ELSE IF @pMODULE_SHORT_NAME = 'ADDI'
		BEGIN
			SET @USER_GROUPNAME = 'ADDI_USER'
			SET @ADMIN_GROUPNAME = 'ADDI_ADMINS'
		END
	ELSE IF @pMODULE_SHORT_NAME = 'GLOBIX'
		BEGIN
			SET @USER_GROUPNAME = 'GLOBIX_USER'
			SET @ADMIN_GROUPNAME = 'GLOBIX_ADMINS'
		END
	ELSE IF @pMODULE_SHORT_NAME = 'UM'
		BEGIN
			SET @USER_GROUPNAME = 'XXXX'
			SET @ADMIN_GROUPNAME = 'UM_ADMINS'
		END

	SELECT @MODULE_GUID = GUID, @MODULE_NAME = NAME FROM TBDD_MODULES WHERE SHORT_NAME = @pMODULE_SHORT_NAME

	IF NOT EXISTS(SELECT GUID FROM TBDD_USER WHERE UPPER(USERNAME) = UPPER(@pUSERNAME))
		BEGIN
			SET @RESULT = 'USER NOT CONFIGURED OR LISTED'
		END
	ELSE
		BEGIN
			SELECT @USER_ID = GUID,@USER_PRENAME = PRENAME,
				@USER_SURNAME = NAME, @USER_SHORTNAME	= SHORTNAME,@USER_EMAIL = EMAIL,@USER_LANGUAGE = LANGUAGE,@USER_DATE_FORMAT = DATE_FORMAT FROM TBDD_USER WHERE UPPER(USERNAME) = UPPER(@pUSERNAME)
			SELECT @USERCOUNT_LOGGED_IN = COUNT(*) FROM TBDD_USER_MODULE_LOG_IN WHERE UPPER(MODULE) = UPPER(@MODULE_NAME) AND CLIENT_ID = @pCLIENTID
			--CHECK USER <20>S IN MODULE_USER_GROUP
			IF EXISTS(select T1.* from TBDD_GROUPS T, TBDD_GROUPS_USER T1 WHERE T.GUID = T1.GROUP_ID AND T1.USER_ID = @USER_ID AND UPPER(T.NAME) = @USER_GROUPNAME)
				BEGIN
					SET @IS_IN_MODULE = 1
					SET @RESULT = 'User is part of Group (' + @USER_GROUPNAME + ')'
					IF EXISTS(select T.* from TBDD_USER_MODULES T WHERE T.USER_ID = @USER_ID AND T.MODULE_ID = @MODULE_GUID)
						BEGIN
							SET @RESULT = @RESULT + '| User is also configured in User-Modules'
							select @IS_ADMIN = T.IS_ADMIN,@USER_RIGHT_FILE_DEL = T.RIGHT1 from TBDD_USER_MODULES T WHERE T.USER_ID = @USER_ID AND T.MODULE_ID = @MODULE_GUID
						END
				END
			ELSE
				BEGIN
					SET @RESULT = 'User not part of group (' + @USER_GROUPNAME + ')'
					IF EXISTS(select T.* from TBDD_USER_MODULES T WHERE T.USER_ID = @USER_ID AND T.MODULE_ID = @MODULE_GUID)
						BEGIN
							SET @RESULT = @RESULT + '| BUT User configured in User-Modules'
							select @IS_ADMIN = T.IS_ADMIN,@USER_RIGHT_FILE_DEL = T.RIGHT1 from TBDD_USER_MODULES T WHERE T.USER_ID = @USER_ID AND T.MODULE_ID = @MODULE_GUID
						END
				END

			IF EXISTS(select T1.* from TBDD_GROUPS T, TBDD_GROUPS_USER T1 WHERE T.GUID = T1.GROUP_ID AND T1.USER_ID = @USER_ID AND UPPER(T.NAME) = @ADMIN_GROUPNAME)
				BEGIN
					SET @RESULT = @RESULT + '| User is part of group (' + @ADMIN_GROUPNAME + ')'
					SET @IS_ADMIN = 1
					SET @IS_IN_MODULE = 1
				END
			
		END
	
INSERT INTO @Table (USER_ID,USER_PRENAME, USER_SURNAME,USER_SHORTNAME,USER_EMAIL,USER_LANGUAGE,USER_DATE_FORMAT, USER_RIGHT_FILE_DEL, MODULE_ACCESS,IS_ADMIN,USERCOUNT_LOGGED_IN, COMMENT)
	 VALUES (@USER_ID,@USER_PRENAME,@USER_SURNAME,@USER_SHORTNAME,@USER_EMAIL,@USER_LANGUAGE,@USER_DATE_FORMAT,@USER_RIGHT_FILE_DEL,@IS_IN_MODULE,@IS_ADMIN,@USERCOUNT_LOGGED_IN,@RESULT)

RETURN
END
GO
ALTER TABLE TBDD_MODULES ADD LICENSE_VALID BIT NOT NULL DEFAULT 1
GO