UPDATE TBDD_MODULES SET DB_VERSION = '1.5.4.2' WHERE SHORT_NAME = 'SIG_ENV_CR'
GO
CREATE VIEW VWSIG_ADMIN_ENVELOPES_BUSY
AS
SELECT TOP 100 PERCENT
	[ENVELOPE_ID]
	,ENVELOPE_UUID
    ,[USER_EMAIL]
    ,[ENVELOPE_STATE] ENVELOPE_STATEID
	,CASE [ENVELOPE_STATE] WHEN 1004 THEN 'Envelope Sent'
		WHEN '1001' THEN 'Envelope Created'
		WHEN '1002' THEN 'Envelope Saved'
		WHEN '1005' THEN 'Envelope partly signed'
		WHEN '1006' THEN 'Envelope completely signed'
		WHEN '1007' THEN 'Envelope Report Created'
	  END as ENVELOPE_STATE
	,[MESSAGE]
    ,[TITLE]
	,[ADDED_WHEN]
	,CHANGED_WHEN
FROM 
	VWSIG_ENVELOPE_DATA where 
	 ENVELOPE_STATE NOT IN (1008,1009) --Archived,Deleted
order by 
	ENVELOPE_ID desc
GO

-- =============================================
-- Author:			DD MS
-- Hier werden Envelopes gefunden, die seit mehr als 20 Minuten unterschrieben sind, wo aber keine Unterschriften gebrannt wurden!
-- Creation date:	28.03.2025
-- =============================================
CREATE PROCEDURE [dbo].[PRDD_CUST_SUPPORT_ERR_7001001]
AS
BEGIN
	SET NOCOUNT ON;

	DECLARE @SUBJECT VARCHAR(100), @BODY VARCHAR(MAX), @EMAIL_TO VARCHAR(100), @MAIL_FROM VARCHAR(200), @COMMENT VARCHAR(MAX), 
			@SYS_DESCR VARCHAR(5), @WF_ID BIGINT, @CUSTOMER_NAME VARCHAR(100),
			@ENV_ID BIGINT, @SENDING_PROFILE TINYINT

	SET @WF_ID = 7001001
	SET @SYS_DESCR = 'PROD'
	SELECT @EMAIL_TO = CAT_STRING FROM TBDD_CATALOG WHERE CAT_TITLE = 'DD_SUPPORT_EMAIL';
	SELECT @SENDING_PROFILE = CONVERT(TINYINT, CAT_STRING) FROM TBDD_CATALOG WHERE CAT_TITLE = 'EMAIL_SENDING_PROFILE';
	SELECT @CUSTOMER_NAME = CAT_STRING FROM TBDD_CATALOG WHERE CAT_TITLE =  'SIG_CUSTOMER_NAME'


	DECLARE curs_PRDD_CUST_SUPPORT_ERR_7001001 CURSOR LOCAL FAST_FORWARD FOR 
		select ENVELOPE_ID from [VWSIG_ENVELOPE_DATA] where ENVELOPE_STATE = 1006 and Datediff(Minute, CHANGED_WHEN,GETDATE()) > 20


	OPEN curs_PRDD_CUST_SUPPORT_ERR_7001001 
	FETCH NEXT FROM curs_PRDD_CUST_SUPPORT_ERR_7001001 INTO @ENV_ID;
	WHILE @@FETCH_STATUS = 0
		BEGIN
		
			SET @SUBJECT = @CUSTOMER_NAME + ' - signFLOW - ' + @SYS_DESCR + ' - Envelope Brennen Signaturen fehlerhaft'
			SET @BODY = '<p>ACHTUNG: für folgende Envelope-ID konnten die Unterschriften bisher nicht gebrannt werden!</p>'
			SET @BODY += '<p>Envelope-ID: <strong>' + CONVERT(VARCHAR(20),@ENV_ID) + '</strong></p>'
			SET @BODY += '<p>Handlungsempfehlung</p>'
			SET @BODY += '<p>1. Das Log des signFLOW Envelope Services prüfen.</p>'
			SET @BODY += '<p>2. Fehler beheben :)</p>'
			SET @BODY += '<p>Erzeugt von Procedure: [PRDD_CUST_SUPPORT_ERR_7001001]</p>'
	
			IF NOT EXISTS(SELECT GUID FROM TBEMLP_EMAIL_OUT WHERE [EMAIL_ADRESS] = @EMAIL_TO AND REFERENCE_ID = @ENV_ID AND WF_ID = @WF_ID AND CONVERT(DATE,ADDED_WHEN) = CONVERT(DATE,GETDATE())
							)
			BEGIN
				PRINT 'NOW INSERTING THE MAIL...'
				--PRINT @EMAIL_TO
				--PRINT @SUBJECT
				--PRINT @BODY
				EXEC PREMAIL_NEW_EMAIL @SENDING_PROFILE, @EMAIL_TO, @SUBJECT, @BODY, '', @ENV_ID, @WF_ID, 'PRDD_CUST_SUPPORT_ERR_7001001';
			END
		
			FETCH NEXT FROM curs_PRDD_CUST_SUPPORT_ERR_7001001 INTO @ENV_ID
		END
	CLOSE curs_PRDD_CUST_SUPPORT_ERR_7001001
	DEALLOCATE curs_PRDD_CUST_SUPPORT_ERR_7001001

END	
GO
IF NOT EXISTS(SELECT CAT_STRING FROM TBDD_CATALOG WHERE CAT_TITLE = 'DD_SUPPORT_EMAIL')
	INSERT INTO TBDD_CATALOG(CAT_TITLE,CAT_STRING) VALUES ('DD_SUPPORT_EMAIL','support-flow@digitaldata.works');
IF NOT EXISTS(SELECT CAT_STRING FROM TBDD_CATALOG WHERE CAT_TITLE = 'EMAIL_SENDING_PROFILE')
	INSERT INTO TBDD_CATALOG(CAT_TITLE,CAT_STRING) VALUES ('EMAIL_SENDING_PROFILE',(SELECT MIN(GUID) FROM TBDD_EMAIL_ACCOUNT));