','
Bitte starten Sie Ihren Process-Manager und bearbeiten die entsprechenden Prozesse.
Vielen Dank.')
GO
--------------------------------------------------------------------------------
CREATE TABLE TBPM_TYPE
(
GUID SMALLINT NOT NULL IDENTITY (1, 1),
BEZEICHNUNG VARCHAR(100) NOT NULL UNIQUE,
ADDED_WHO VARCHAR(30) NOT NULL DEFAULT 'Digital Data',
ADDED_WHEN DATETIME NOT NULL DEFAULT (GETDATE()),
CHANGED_WHO VARCHAR(30),
CHANGED_WHEN DATETIME,
CONSTRAINT PK_TBPM_TYPE_GUID PRIMARY KEY (GUID)
)
GO
INSERT INTO TBPM_TYPE(BEZEICHNUNG) VALUES ('Man. Validation')
GO
INSERT INTO TBPM_TYPE(BEZEICHNUNG) VALUES ('Automatism')
GO
CREATE TRIGGER TBPM_TYPE_AFT_UPD ON TBPM_TYPE
FOR UPDATE
AS
UPDATE TBPM_TYPE SET CHANGED_WHEN = GETDATE()
FROM INSERTED
WHERE TBPM_TYPE.GUID = INSERTED.GUID
GO
CREATE TABLE TBPM_PROFILE
(
GUID INTEGER NOT NULL IDENTITY (1, 1),
NAME VARCHAR(100) NOT NULL UNIQUE,
TITLE VARCHAR(150) NOT NULL DEFAULT 'DEFAULT-TITLE',
WD_OBJECTTYPE VARCHAR(200) NOT NULL,
PRIORITY INTEGER NOT NULL DEFAULT 1,
DESCRIPTION VARCHAR(250) ,
TYPE SMALLINT NOT NULL,
LOG_INDEX VARCHAR(50) NOT NULL DEFAULT '',
IN_WORK BIT NOT NULL DEFAULT 0,
ACTIVE BIT NOT NULL DEFAULT 0,
WD_SEARCH VARCHAR(500) NOT NULL,
PM_VEKTOR_INDEX VARCHAR(50) NOT NULL DEFAULT '',
NO_OF_DOCUMENTS INTEGER NOT NULL DEFAULT 0,
FINAL_PROFILE BIT NOT NULL DEFAULT 0,
FINAL_TEXT VARCHAR(250),
MOVE2FOLDER VARCHAR(1000),
SORT_BY_LATEST BIT NOT NULL DEFAULT 0,
WORK_HISTORY_ENTRY VARCHAR(500),
ANNOTATE_ALL_WORK_HISTORY_ENTRIES BIT NOT NULL DEFAULT 0,
ANNOTATE_WORK_HISTORY_ENTRY BIT NOT NULL DEFAULT 0,
SQL_VIEW VARCHAR(MAX) NOT NULL DEFAULT '',
SQL_PROFILE_MAIN_VIEW VARCHAR(MAX) NOT NULL DEFAULT '',
SQL_GROUP_COLOR VARCHAR(MAX) NOT NULL DEFAULT '',
SQL_GROUP_TEXT VARCHAR(MAX) NOT NULL DEFAULT '',
ADDED_WHO VARCHAR(30) NOT NULL DEFAULT 'Digital Data',
ADDED_WHEN DATETIME NOT NULL DEFAULT (GETDATE()),
CHANGED_WHO VARCHAR(30),
CHANGED_WHEN DATETIME,
CONSTRAINT PK_TBPM_PROFILE_GUID PRIMARY KEY (GUID),
CONSTRAINT FK_TBPM_PROFILE_TYPE FOREIGN KEY (TYPE) REFERENCES TBPM_TYPE (GUID)
)
GO
--ALTER TABLE dbo.TBPM_PROFILE WITH NOCHECK
--ADD CONSTRAINT FK_TBPM_PROFILE_TYPE FOREIGN KEY (TYPE) REFERENCES TBPM_TYPE (GUID) ;
CREATE TRIGGER TBPM_PROFILE_AFT_UPD ON TBPM_PROFILE
FOR UPDATE
AS
UPDATE TBPM_PROFILE SET CHANGED_WHEN = GETDATE()
FROM INSERTED
WHERE TBPM_PROFILE.GUID = INSERTED.GUID
GO
------------------------------------------------------------------------------
CREATE TABLE TBPM_PROFILE_FILES
(
GUID INTEGER IDENTITY(1,1),
DOC_ID INTEGER NOT NULL DEFAULT 0,
PROFIL_ID INTEGER NOT NULL,
FILE_PATH VARCHAR(1000),
EDIT BIT NOT NULL DEFAULT 0,
DMS_ERSTELLT_DATE DATE,
IN_WORK BIT NOT NULL DEFAULT 0,
WORK_USER VARCHAR(100),
ACTIVE BIT NOT NULL DEFAULT 0,
REFRESHED BIT NOT NULL DEFAULT 1,
REFRESHED_WHEN DATETIME,
ERSTELLTWER VARCHAR(50) DEFAULT 'PM_REFRESH_MANAGER' NOT NULL,
ERSTELLTWANN DATETIME DEFAULT GETDATE() NOT NULL,
CONSTRAINT PK_TBPM_PROFILE_FILES_GUID PRIMARY KEY(GUID),
CONSTRAINT FK_TBPM_PROFILE_FILES_PROFIL_ID FOREIGN KEY (PROFIL_ID) REFERENCES TBPM_PROFILE (GUID)
)
GO
------------------------------------------------------------------------------
CREATE TABLE TBPM_FILES_USER_NOT_INDEXED
(
USR_NAME VARCHAR(50),
PROFIL_ID INTEGER,
FILE_PATH VARCHAR(500),
UNIQUE (USR_NAME,PROFIL_ID,FILE_PATH)
)
GO
------------------------------------------------------------------------------
CREATE TABLE TBPM_FILES_WORK_HISTORY
(
GUID INTEGER IDENTITY(1,1),
PROFIL_ID INTEGER NOT NULL,
DOC_ID INTEGER NOT NULL DEFAULT 0,
WORKED_BY VARCHAR(100) NOT NULL,
WORKED_WHEN DATETIME NOT NULL DEFAULT GETDATE(),
WORKED_WHERE VARCHAR(100) NOT NULL,
STATUS_COMMENT VARCHAR(500),
COMMENT VARCHAR(MAX),
CONSTRAINT [PK_TBPM_FILES_WORK_HISTORY] PRIMARY KEY (GUID)
)
GO
------------------------------------------------------------------------------
CREATE TABLE TBPM_ERROR_LOG
(
GUID INT NOT NULL IDENTITY (1, 1),
PROFIL_ID INTEGER NOT NULL,
ERROR_MSG VARCHAR(1000) NOT NULL,
ADDED_WHO VARCHAR(50) NOT NULL,
ADDED_WHEN DATETIME NOT NULL DEFAULT GETDATE(),
MACHINE_NAME VARCHAR(50),
CONSTRAINT PK_TBPM_ERROR_LOG_GUID PRIMARY KEY(GUID),
CONSTRAINT FK_TBPM_ERROR_LOG_PROFILE FOREIGN KEY (PROFIL_ID) REFERENCES TBPM_PROFILE (GUID)
)
GO
CREATE TABLE TBPM_PROFILE_CONTROLS
(
GUID INTEGER NOT NULL IDENTITY (1, 1),
PROFIL_ID INTEGER NOT NULL,
NAME VARCHAR(100) NOT NULL,
CTRL_TYPE VARCHAR(10) NOT NULL, --TXT,LBL,COMBO,DTP
CTRL_TEXT VARCHAR(50) NOT NULL DEFAULT 'CTRL TEXT',
X_LOC FLOAT NOT NULL,
Y_LOC FLOAT NOT NULL,
HEIGHT SMALLINT NOT NULL DEFAULT 25,
WIDTH SMALLINT NOT NULL DEFAULT 200,
INDEX_NAME VARCHAR(100),
TYP VARCHAR(50),
[VALIDATION] BIT NOT NULL DEFAULT 0,
CHOICE_LIST VARCHAR(50),
CONNECTION_ID SMALLINT,
DEFAULT_VALUE VARCHAR(100),
MULTISELECT BIT DEFAULT 0 NOT NULL,
VKT_ADD_ITEM BIT DEFAULT 0 NOT NULL,
VKT_PREVENT_MULTIPLE_VALUES BIT DEFAULT 0 NOT NULL,
SQL_UEBERPRUEFUNG VARCHAR(MAX) DEFAULT '',
REGEX_MESSAGE_DE VARCHAR(1000) NOT NULL DEFAULT '',
REGEX_MESSAGE_EN VARCHAR(1000) NOT NULL DEFAULT '',
[READ_ONLY] BIT NOT NULL DEFAULT 0,
LOAD_IDX_VALUE BIT NOT NULL DEFAULT 1,
FONT_STYLE smallint,
FONT_SIZE smallint,
FONT_FAMILY varchar(50),
FONT_COLOR bigint,
ADDED_WHO VARCHAR(30) NOT NULL DEFAULT 'Digital Data',
ADDED_WHEN DATETIME NOT NULL DEFAULT (GETDATE()),
CHANGED_WHO VARCHAR(30),
CHANGED_WHEN DATETIME,
CONSTRAINT PK_TBPM_PROFILE_CONTROLS_GUID PRIMARY KEY (GUID),
CONSTRAINT FK_TBPM_PROFILE_CONTROLS_PROFILE FOREIGN KEY (PROFIL_ID) REFERENCES TBPM_PROFILE (GUID),
CONSTRAINT UQ_TBPM_PROFILE_CONTROLS UNIQUE(PROFIL_ID,NAME)
)
GO
CREATE TRIGGER TBPM_PROFILE_CONTROLS_AFT_UPD ON TBPM_PROFILE_CONTROLS
FOR UPDATE
AS
UPDATE TBPM_PROFILE_CONTROLS SET CHANGED_WHEN = GETDATE()
FROM INSERTED
WHERE TBPM_PROFILE_CONTROLS.GUID = INSERTED.GUID
GO
CREATE TABLE TBPM_CONTROL_TABLE
(
GUID INTEGER NOT NULL IDENTITY (1, 1),
CONTROL_ID INTEGER NOT NULL,
SPALTENNAME VARCHAR(100) NOT NULL,
SPALTEN_HEADER VARCHAR(100) NOT NULL,
SPALTENBREITE INTEGER NOT NULL,
[VALIDATION] BIT NOT NULL DEFAULT 0,
CHOICE_LIST VARCHAR(50),
CONNECTION_ID SMALLINT,
SQL_COMMAND VARCHAR(2000),
REGEX_MESSAGE_DE VARCHAR(1000) NOT NULL DEFAULT '',
REGEX_MESSAGE_EN VARCHAR(1000) NOT NULL DEFAULT '',
REGEX_MATCH VARCHAR(1000) NOT NULL DEFAULT '',
[READ_ONLY] BIT NOT NULL DEFAULT 0,
LOAD_IDX_VALUE BIT NOT NULL DEFAULT 1,
ADDED_WHO VARCHAR(30) NOT NULL DEFAULT 'Digital Data',
ADDED_WHEN DATETIME NOT NULL DEFAULT (GETDATE()),
CHANGED_WHO VARCHAR(30),
CHANGED_WHEN DATETIME,
CONSTRAINT PK_TBPM_CONTROL_TABLE_GUID PRIMARY KEY (GUID),
CONSTRAINT FK_TBPM_CONTROL_TABLE_CONTROL FOREIGN KEY (CONTROL_ID) REFERENCES TBPM_PROFILE_CONTROLS (GUID)
)
GO
CREATE TRIGGER TBPM_CONTROL_TABLE_AFT_UPD ON TBPM_CONTROL_TABLE
FOR UPDATE
AS
UPDATE TBPM_CONTROL_TABLE SET CHANGED_WHEN = GETDATE()
FROM INSERTED
WHERE TBPM_CONTROL_TABLE.GUID = INSERTED.GUID
GO
----------------
CREATE TABLE TBPM_PROFILE_USER
(
GUID INTEGER NOT NULL IDENTITY (1, 1),
PROFIL_ID INTEGER NOT NULL,
USER_ID INTEGER NOT NULL,
ADDED_WHO VARCHAR(30) NOT NULL DEFAULT 'Digital Data',
ADDED_WHEN DATETIME NOT NULL DEFAULT (GETDATE()),
CHANGED_WHO VARCHAR(30),
CHANGED_WHEN DATETIME,
CONSTRAINT PK_TBPM_PROFILE_USER_GUID PRIMARY KEY (GUID),
UNIQUE (PROFIL_ID,USER_ID),
CONSTRAINT FK_TBPM_PROFILE_USER_PROFILE FOREIGN KEY (PROFIL_ID) REFERENCES TBPM_PROFILE (GUID),
CONSTRAINT FK_TBPM_PROFILE_USER_USER FOREIGN KEY (USER_ID) REFERENCES TBDD_USER (GUID),
CONSTRAINT UQ_TBPM_PROFILE_USER UNIQUE (PROFIL_ID,USER_ID)
)
GO
CREATE TRIGGER TBPM_PROFILE_USER_AFT_UPD ON TBPM_PROFILE_USER
FOR UPDATE
AS
UPDATE TBPM_PROFILE_USER SET CHANGED_WHEN = GETDATE()
FROM INSERTED
WHERE TBPM_PROFILE_USER.GUID = INSERTED.GUID
GO
CREATE TABLE TBPM_PROFILE_GROUP
(
GUID INTEGER NOT NULL IDENTITY (1, 1),
PROFIL_ID INTEGER NOT NULL,
GROUP_ID INTEGER NOT NULL,
ADDED_WHO VARCHAR(30) NOT NULL DEFAULT 'Digital Data',
ADDED_WHEN DATETIME NOT NULL DEFAULT (GETDATE()),
CHANGED_WHO VARCHAR(30),
CHANGED_WHEN DATETIME,
CONSTRAINT PK_TBPM_PROFILE_GROUP_GUID PRIMARY KEY (GUID),
UNIQUE (PROFIL_ID,GROUP_ID),
CONSTRAINT FK_TBPM_PROFILE_GROUP_PROFILE FOREIGN KEY (PROFIL_ID) REFERENCES TBPM_PROFILE (GUID),
CONSTRAINT FK_TBPM_PROFILE_GROUP_GROUP FOREIGN KEY (GROUP_ID) REFERENCES TBDD_GROUPS (GUID),
CONSTRAINT UQ_TBPM_PROFILE_GROUP UNIQUE (PROFIL_ID,GROUP_ID)
)
GO
CREATE TRIGGER TBPM_PROFILE_GROUP_AFT_UPD ON TBPM_PROFILE_GROUP
FOR UPDATE
AS
UPDATE TBPM_PROFILE_GROUP SET CHANGED_WHEN = GETDATE()
FROM INSERTED
WHERE TBPM_PROFILE_GROUP.GUID = INSERTED.GUID
GO
CREATE TABLE TBPM_PROFILE_FINAL_INDEXING
(
GUID INTEGER NOT NULL IDENTITY (1, 1),
PROFIL_ID INTEGER NOT NULL,
CONNECTION_ID SMALLINT NOT NULL DEFAULT 0,
SQL_COMMAND VARCHAR(MAX) NOT NULL DEFAULT '',
INDEXNAME VARCHAR(100) NOT NULL,
VALUE VARCHAR(100) NOT NULL,
ACTIVE BIT NOT NULL DEFAULT 1,
[DESCRIPTION] VARCHAR(MAX) NOT NULL DEFAULT '',
PREVENT_DUPLICATES BIT NOT NULL DEFAULT (0),
ALLOW_NEW_VALUES BIT NOT NULL DEFAULT (0),
ADDED_WHO VARCHAR(30) NOT NULL DEFAULT 'Digital Data',
ADDED_WHEN DATETIME NOT NULL DEFAULT (GETDATE()),
CHANGED_WHO VARCHAR(30),
CHANGED_WHEN DATETIME,
CONSTRAINT PK_TBPM_PROFILE_FINAL_INDEXING_GUID PRIMARY KEY (GUID),
CONSTRAINT FK_TBPM_PROFILE_FINAL_INDEXING_PROFILE FOREIGN KEY (PROFIL_ID) REFERENCES TBPM_PROFILE (GUID)
)
GO
CREATE TRIGGER TBPM_PROFILE_FINAL_INDEXING_AFT_UPD ON TBPM_PROFILE_FINAL_INDEXING
FOR UPDATE
AS
UPDATE TBPM_PROFILE_FINAL_INDEXING SET CHANGED_WHEN = GETDATE()
FROM INSERTED
WHERE TBPM_PROFILE_FINAL_INDEXING.GUID = INSERTED.GUID
GO
CREATE TABLE TBPM_PROFILE_SEARCH
(
GUID INTEGER IDENTITY(1,1),
PROFILE_ID INTEGER NOT NULL,
TYPE VARCHAR(50) NOT NULL DEFAULT 'SQL',
CONN_ID INTEGER NOT NULL DEFAULT '0',
TAB_TITLE VARCHAR(50) NOT NULL DEFAULT 'UndefinedTitle',
LOAD_ON_START bit NOT NULL DEFAULT 1,
TAB_INDEX TINYINT DEFAULT 0 NOT NULL,
SQL_COMMAND VARCHAR(3000) NOT NULL,
RUN_MANUAL BIT DEFAULT 1 NOT NULL,
ACTIVE BIT DEFAULT 0 NOT NULL,
CREATED_WHO VARCHAR(50) DEFAULT 'DEFAULT' NOT NULL,
CREATED_WHEN DATETIME DEFAULT GETDATE(),
CONSTRAINT PK_TBPM_PROFILE_SEARCH PRIMARY KEY(GUID),
CONSTRAINT FK_TBPM_PROFILE_SEARCH_PROFILE_ID FOREIGN KEY (PROFILE_ID) REFERENCES TBPM_PROFILE (GUID)
)
GO
CREATE TABLE TBPM_MAIN_VIEW_GROUPS
(
GUID INTEGER IDENTITY(1,1),
GROUPNAME VARCHAR(100) NOT NULL,
ACTIVE BIT DEFAULT 1 NOT NULL,
CREATED_WHO VARCHAR(50) DEFAULT 'DEFAULT' NOT NULL,
CREATED_WHEN DATETIME DEFAULT GETDATE(),
CHANGED_WHO VARCHAR(50) DEFAULT 'DEFAULT' NOT NULL,
CHANGED_WHEN DATETIME DEFAULT GETDATE(),
CONSTRAINT PK_TBPM_MAIN_VIEW_GROUPS PRIMARY KEY(GUID)
)
GO
CREATE TRIGGER [dbo].[TBPM_MAIN_VIEW_GROUPS_AFT_UPD] ON [dbo].[TBPM_MAIN_VIEW_GROUPS]
FOR UPDATE
AS
BEGIN
UPDATE TBPM_MAIN_VIEW_GROUPS SET CHANGED_WHEN = GETDATE() FROM INSERTED WHERE TBPM_MAIN_VIEW_GROUPS.GUID = INSERTED.GUID
END
GO
INSERT INTO TBPM_MAIN_VIEW_GROUPS (GROUPNAME) VALUES ('GROUP_TEXT')
GO
CREATE TABLE [dbo].[TBPM_CHART](
GUID INTEGER IDENTITY(1,1) NOT NULL,
PROFILE_ID INTEGER NOT NULL,
SQL_COMMAND VARCHAR(MAX) NOT NULL,
TYPE_CHART VARCHAR(50) NOT NULL,
ARGUMENT VARCHAR(50) NOT NULL,
[VALUE] VARCHAR(50) NOT NULL,
TITLE VARCHAR(50) NOT NULL DEFAULT '',
ADDED_WHO VARCHAR(50) DEFAULT '',
ADDED_WHEN DATETIME DEFAULT GETDATE(),
CHANGED_WHO VARCHAR(50),
CHANGED_WHEN DATETIME,
GROUP_ID VARCHAR(50) DEFAULT '',
CONSTRAINT PK_TBPM_CHART_GUID PRIMARY KEY (GUID),
CONSTRAINT FK_TBPM_CHART_PROFILE FOREIGN KEY (PROFILE_ID) REFERENCES TBPM_PROFILE (GUID)
)
GO
--PROCEDURES
CREATE PROCEDURE [dbo].[PRPM_DELETE_USER](@pUSER_ID INT)
AS
BEGIN TRY
IF OBJECT_ID(N'dbo.TBPM_PROFILE_USER', N'U') IS NOT NULL
DELETE FROM TBPM_PROFILE_USER WHERE USER_ID = @pUSER_ID
IF OBJECT_ID(N'dbo.TBPM_PROFILE_USER', N'U') IS NOT NULL
DELETE FROM TBPM_PROFILE_USER WHERE USER_ID = @pUSER_ID
DELETE FROM TBDD_USER_MODULES WHERE USER_ID = @pUSER_ID AND MODULE_ID = (SELECT GUID FROM TBDD_MODULES WHERE SHORT_NAME = 'PM')
END TRY
BEGIN CATCH
PRINT 'FEHLER IN PROCEDURE: ' + CONVERT(VARCHAR(30),ERROR_PROCEDURE()) + ' - ZEILE: ' + CONVERT(VARCHAR(10),ERROR_LINE())
+ ' - FEHLER-MESSAGE: '
+ CONVERT(VARCHAR(500),ERROR_MESSAGE())
END CATCH
GO
CREATE PROCEDURE [dbo].[PRPM_REMOVE_NE_FILES]
AS
DECLARE
@DOC_ID INTEGER
DECLARE c_REDO CURSOR FOR
select DOC_ID from TBPM_PROFILE_FILES
OPEN c_REDO
FETCH NEXT FROM c_REDO INTO @DOC_ID
WHILE @@FETCH_STATUS = 0
BEGIN
IF NOT EXISTS(SELECT dwDocID FROM windream60.dbo.BaseAttributes where dwDocID = @DOC_ID)
DELETE FROM TBPM_PROFILE_FILES WHERE DOC_ID = @DOC_ID
FETCH NEXT FROM c_REDO INTO @DOC_ID
END
CLOSE c_REDO
DEALLOCATE c_REDO
GO
--FUNCTIONS
CREATE FUNCTION [dbo].[FNPM_PROFILE_GROUP_TEXT](@pPROFIL_ID AS INTEGER)
RETURNS VARCHAR(250)
AS
BEGIN
DECLARE @RESULT VARCHAR(250)
SELECT @RESULT = TITLE FROM TBPM_PROFILE WHERE GUID = @pPROFIL_ID
IF @pPROFIL_ID = 1
SET @RESULT = @RESULT + ' | Additional Text for Profile 1'
ELSE
SET @RESULT = @RESULT + ' | YourTextVariabel in FNPM_PROFILE_GROUP_TEXT'
RETURN @RESULT
END
GO
--GRANT EXECUTE ON [dbo].[FNPM_PROFILE_GROUP_TEXT] TO [dd_ecm]
--GO
CREATE FUNCTION [dbo].[FNPM_LAST_WORKUSER_DOC](@pPROFIL_ID INTEGER,@pDOC_ID INTEGER)
RETURNS VARCHAR(250)
AS
BEGIN
DECLARE @RESULT VARCHAR(250)
SELECT @RESULT = WORKED_BY FROM TBPM_FILES_WORK_HISTORY WHERE GUID =
(SELECT MAX(GUID) FROM TBPM_FILES_WORK_HISTORY WHERE PROFIL_ID = @pPROFIL_ID AND DOC_ID = @pDOC_ID)
IF LEN(@RESULT) = 0
SET @RESULT = ''
RETURN @RESULT
END
GO
--GRANT EXECUTE ON [dbo].[FNPM_LAST_WORKUSER_DOC] TO [dd_ecm]
--GO
CREATE FUNCTION [dbo].[FNPM_LAST_EDITED_DOC](@pPROFIL_ID INTEGER,@pDOC_ID INTEGER)
RETURNS DATETIME
AS
BEGIN
DECLARE @RESULT DATETIME
SELECT @RESULT = WORKED_WHEN FROM TBPM_FILES_WORK_HISTORY WHERE GUID =
(SELECT MAX(GUID) FROM TBPM_FILES_WORK_HISTORY WHERE PROFIL_ID = @pPROFIL_ID AND DOC_ID = @pDOC_ID)
IF LEN(@RESULT) = 0
SET @RESULT = ''
RETURN @RESULT
END
GO
GO
--GRANT EXECUTE ON [dbo].[FNPM_LAST_EDITED_DOC] TO [dd_ecm]
--GO
CREATE FUNCTION [dbo].[FNPM_PROFILE_GROUP_COLOR](@pPROFIL_ID AS INTEGER)
RETURNS VARCHAR(20)
AS
BEGIN
DECLARE @RESULT VARCHAR(20)
SET @RESULT = 'Grey'
IF @pPROFIL_ID = 1
SET @RESULT = 'Red'
ELSE
SET @RESULT = 'Yellow'
RETURN @RESULT
END
GO
--GRANT EXECUTE ON [dbo].[FNPM_PROFILE_GROUP_COLOR] TO [dd_ecm]
--GO
--GRANT EXECUTE ON [dbo].[FNPM_PROFILE_GROUP_TEXT] TO [dd_ecm]
--GO
CREATE FUNCTION [dbo].[FNPM_GET_FREE_USER_FOR_PROFILE] (@pPROFILE_ID INTEGER)
RETURNS
@Table TABLE
(SequentialOrder INT IDENTITY(1, 1),
USER_ID INTEGER,
USER_NAME VARCHAR(50),
USER_PRENAME VARCHAR(50),
USER_SURNAME VARCHAR(50),
USER_SHORTNAME VARCHAR(50),
USER_EMAIL VARCHAR(100),
USER_LANGUAGE VARCHAR(10),
USER_COMMENT VARCHAR(500))
AS
BEGIN
/* This function returns all free users per profile */
INSERT INTO @Table (USER_ID,USER_NAME, USER_PRENAME, USER_SURNAME,USER_SHORTNAME,USER_EMAIL,USER_LANGUAGE,USER_COMMENT)
SELECT
T.USER_ID
,T.USER_NAME
,T.USER_PRENAME
,T.USER_SURNAME
,T.USER_SHORTNAME
,T.USER_EMAIL
,T.USER_LANGUAGE
,T.USER_COMMENT
FROM
[dbo].FNDD_GET_USER_FOR_MODULE ('PM',1) T WHERE T.USER_ID NOT IN (SELECT USER_ID FROM TBPM_PROFILE_USER WHERE PROFIL_ID = @pPROFILE_ID)
RETURN
END
GO
CREATE FUNCTION [dbo].[FNPM_GET_ACTIVE_PROFILES_USER] (@USER_ID INTEGER)
RETURNS
@Table TABLE
(SCOPE VARCHAR(20),PROFILE_ID INTEGER, P_NAME VARCHAR(50),SequentialOrder INT IDENTITY(1, 1))
AS
BEGIN
DECLARE
@P_ID INTEGER,
@P_NAME VARCHAR(50)
DECLARE cursProfileUser CURSOR FOR
select T.PROFIL_ID, T1.NAME FROM TBPM_PROFILE_USER T, TBPM_PROFILE T1 WHERE T.PROFIL_ID = T1.GUID AND T.USER_ID = @USER_ID
OPEN cursProfileUser
FETCH NEXT FROM cursProfileUser INTO @P_ID,@P_NAME
WHILE @@FETCH_STATUS = 0
BEGIN
INSERT INTO @Table (SCOPE,PROFILE_ID,P_NAME) VALUES ('PROFILE-USER',@P_ID,@P_NAME)
FETCH NEXT FROM cursProfileUser INTO @P_ID,@P_NAME
END
CLOSE cursProfileUser
DEALLOCATE cursProfileUser
DECLARE cursProfileGROUP CURSOR FOR
SELECT T.PROFIL_ID, TP.NAME FROM TBPM_PROFILE_GROUP T,TBDD_GROUPS T1,TBPM_PROFILE TP,TBDD_GROUPS_USER T2 WHERE
T.GROUP_ID = T1.GUID AND T.PROFIL_ID = TP.GUID AND TP.TYPE = 1 AND T1.GUID = T2.GROUP_ID AND T2.USER_ID = @USER_ID
OPEN cursProfileGROUP
FETCH NEXT FROM cursProfileGROUP INTO @P_ID,@P_NAME
WHILE @@FETCH_STATUS = 0
BEGIN
IF NOT EXISTS(SELECT * FROM @Table WHERE PROFILE_ID = @P_ID)
INSERT INTO @Table (SCOPE,PROFILE_ID,P_NAME) VALUES ('PROFILE-GROUP',@P_ID,@P_NAME)
FETCH NEXT FROM cursProfileGROUP INTO @P_ID,@P_NAME
END
CLOSE cursProfileGROUP
DEALLOCATE cursProfileGROUP
RETURN
END
GO
--VIEWS
CREATE VIEW [dbo].[VWPM_CONTROL_INDEX] AS
SELECT TOP 100 PERCENT
T1.GUID,
T.GUID PROFIL_ID,
T.NAME PROFIL_NAME,
T.LOG_INDEX,
T1.NAME CTRL_NAME,
T1.CTRL_TYPE,
T1.CTRL_TEXT,
T1.X_LOC,
T1.Y_LOC,
T1.FONT_COLOR,
T1.FONT_FAMILY,
T1.FONT_SIZE,
T1.FONT_STYLE,
T1.WIDTH,
T1.HEIGHT,
COALESCE(T1.INDEX_NAME,'') INDEX_NAME,
T1.VALIDATION,
T1.CHOICE_LIST,
T1.TYP,
T1.CONNECTION_ID,
CASE WHEN T1.[SQL_UEBERPRUEFUNG] IS NULL THEN '' ELSE T1.[SQL_UEBERPRUEFUNG] END AS [SQL_UEBERPRUEFUNG],
T1.[READ_ONLY],
T1.LOAD_IDX_VALUE,
T1.DEFAULT_VALUE,
T1.REGEX_MESSAGE_DE,
T1.REGEX_MESSAGE_EN
FROM
TBPM_PROFILE T,
TBPM_PROFILE_CONTROLS T1
WHERE
T.GUID = T1.PROFIL_ID
ORDER BY
T.GUID,
T1.X_LOC,
T1.Y_LOC
GO
CREATE VIEW [dbo].[VWPM_PROFILE_USER_UNION] AS
SELECT
'USER' SCOPE,
T.GUID PROFIL_ID,
T.NAME PROFIL_NAME,
T.TITLE,
T.DESCRIPTION,
T.WD_OBJECTTYPE,
T.PRIORITY,
T.WD_SEARCH,
COALESCE(T.MOVE2FOLDER,'') as MOVE2Folder,
T.ACTIVE,
T.IN_WORK,
T.NO_OF_DOCUMENTS,
T.FINAL_PROFILE,
T.FINAL_TEXT,
T.LOG_INDEX,
T.PM_VEKTOR_INDEX,
T2.GUID AS USER_ID,
T2.PRENAME,
T2.NAME,
T2.USERNAME,
T2.EMAIL,
--T2.PM_RIGHT_FILE_DELETE as RIGHT_FILE_DELETE,
[dbo].[FNPM_PROFILE_GROUP_COLOR] (T.GUID) AS 'GROUP_COLOR',
[dbo].[FNPM_PROFILE_GROUP_TEXT] (T.GUID) AS 'GROUP_TEXT'
FROM
TBPM_PROFILE T,
TBPM_PROFILE_USER T1,
TBDD_USER T2
WHERE
T.TYPE = 1 AND
T.GUID = T1.PROFIL_ID AND
T1.USER_ID = T2.GUID
UNION
SELECT
'GROUP' SCOPE,
T.GUID PROFIL_ID,
T.NAME PROFIL_NAME,
T.TITLE,
T.DESCRIPTION,
T.WD_OBJECTTYPE,
T.PRIORITY,
T.WD_SEARCH,
COALESCE(T.MOVE2FOLDER,'') as MOVE2Folder,
T.ACTIVE,
T.IN_WORK,
T.NO_OF_DOCUMENTS,
T.FINAL_PROFILE,
T.FINAL_TEXT,
T.LOG_INDEX,
T.PM_VEKTOR_INDEX,
T4.GUID AS USER_ID,
T4.PRENAME,
T4.NAME,
T4.USERNAME,
T4.EMAIL,
--T4.PM_RIGHT_FILE_DELETE as RIGHT_FILE_DELETE,
[dbo].[FNPM_PROFILE_GROUP_COLOR] (T.GUID) AS 'GROUP_COLOR',
[dbo].[FNPM_PROFILE_GROUP_TEXT] (T.GUID) AS 'GROUP_TEXT'
FROM
TBPM_PROFILE T,
TBPM_PROFILE_GROUP T1,
TBDD_GROUPS T2,
TBDD_GROUPS_USER T3,
TBDD_USER T4
WHERE
T.TYPE = 1 AND
T.GUID = T1.PROFIL_ID AND
T1.GROUP_ID = T2.GUID AND
T2.GUID = T3.GROUP_ID AND
T3.USER_ID = T4.GUID
GO
CREATE VIEW VWPM_PROFILE_USER AS
SELECT DISTINCT * FROM VWPM_PROFILE_USER_UNION
GO
CREATE VIEW [dbo].[VWPM_EMAIL_PROFIL] AS
SELECT
T.PROFIL_ID,
T2.TITLE AS PROFIL_TITLE,
T2.NAME AS PROFIL_NAME,
T.USER_ID,
T1.USERNAME,
T1.EMAIL,
'' AS LAST_HOUR,
'' as EMAIL_ONCE_DAY,
(SELECT COUNT(GUID) FROM TBPM_PROFILE_FILES WHERE PROFIL_ID = T.PROFIL_ID) AS ANZ_FILES
FROM
TBPM_PROFILE_USER T,
TBDD_USER T1,
TBPM_PROFILE T2
WHERE
T.USER_ID = T1.GUID AND
T.PROFIL_ID = T2.GUID AND
T1.EMAIL IS NOT NULL
GO
CREATE VIEW VWPM_PROFILE_ACTIVE AS
SELECT
T1.*,
(SELECT COUNT(GUID) FROM TBPM_PROFILE_FILES WHERE PROFIL_ID = T1.GUID) AS FILE_COUNT,
[dbo].[FNPM_PROFILE_GROUP_COLOR] (T1.GUID) AS 'GROUP_COLOR',
[dbo].[FNPM_PROFILE_GROUP_TEXT] (T1.GUID) AS 'GROUP_TEXT'
FROM
TBPM_PROFILE T1
WHERE
T1.ACTIVE = 1
GO
UPDATE TBPM_KONFIGURATION SET SQL_PROFILE_MAIN_VIEW = '
/*## Following Columns need to be part of sql ##
TL_STATE Returns the TrafficLight-State for each doc (1=Red;2=Orange;3=Green)
PROFILE_ID TITLE Profile-Title used for default-grouping
DOC_ID
FULL_FILE_PATH
LAST USE
LAST EDITED */
--DECLARE @USER_ID INTEGER
--SET @USER_ID = 1
SELECT
T.GUID,
DATEDIFF(DAY, [dbo].[FNPM_LAST_EDITED_DOC] (T.PROFIL_ID,T.DOC_ID),GETDATE()) AS [Days in],
Case DATEDIFF(DAY, [dbo].[FNPM_LAST_EDITED_DOC] (T.PROFIL_ID,T.DOC_ID),GETDATE()) WHEN 0 THEN 3 WHEN 1 THEN 2 WHEN 2 THEN 1 ELSE 3 END AS TL_STATE,
T.PROFIL_ID AS PROFILE_ID,
T.DOC_ID,
T.FILE_PATH AS FULL_FILE_PATH,
TWM_BA.szLongName as Dateiname,
TWM_BA.szText36 AS Dokumentart,
--TWM_BA.szText35 AS [weitergeleitet an],
--TWM_BA.lfFloat14 AS [Rechnungs Summe],
--ISNULLTWM_BA.szText14 AS Buchungskreis,
--TWM_BA.szText08 AS Kreditor,
T.DMS_ERSTELLT_DATE AS [Erhalten wann],
[dbo].[FNPM_LAST_WORKUSER_DOC] (T.PROFIL_ID,T.DOC_ID) AS ''Last User'',
[dbo].[FNPM_LAST_EDITED_DOC] (T.PROFIL_ID,T.DOC_ID) AS ''Last edited'',
[dbo].[FNPM_PROFILE_GROUP_COLOR] (T.PROFIL_ID) AS ''GROUP_COLOR'',
[dbo].[FNPM_PROFILE_GROUP_TEXT] (T.PROFIL_ID) AS ''GROUP_TEXT''
FROM TBPM_PROFILE_FILES T,
TBPM_PROFILE T1,
TBDD_USER T2,
windream60.dbo.BaseAttributes TWM_BA WHERE T.EDIT = 0 AND T.IN_WORK = 0 AND T.ACTIVE = 1 AND T.PROFIL_ID = T1.GUID AND T1.GUID in (SELECT PROFIL_ID FROM [dbo].[FNPM_GET_ACTIVE_PROFILES_USER] ({#USER#USER_ID})) AND T1.ACTIVE = 1 And T2.GUID = {#USER#USER_ID}
AND T.DOC_ID = TWM_BA.dwDocID ORDER By T1.PRIORITY'
WHERE GUID = 1
GO
CREATE FUNCTION [dbo].[FNDD_GET_WINDREAM_FILE_PATH] (@pDOCID BIGINT)
RETURNS VARCHAR(MAX)
AS
BEGIN
DECLARE
@RESULT VARCHAR(MAX),
@DOCID BIGINT,
@a TINYINT = 1,
@i TINYINT = 0,
@PARENT_ID BIGINT,
@DATEINAME NVARCHAR(255),
@PARENTNAME NVARCHAR(255),
@FSFLAGS INT,
@WM_PREFIX VARCHAR(50)
SELECT @WM_PREFIX = WM_REL_PATH from tbpm_KONFIGURATION WHERE GUID = 1
SELECT @FSFLAGS = dwFSFlags FROM windream60.dbo.BaseAttributes WHERE dwDocID = @pDOCID
IF @FSFLAGS = 16
BEGIN
SET @RESULT = 'THIS IS NOT A FILE!'
END
ELSE
BEGIN
SELECT @DATEINAME = szLongName,@PARENT_ID = dwParentID FROM windream60.dbo.BaseAttributes WHERE dwDocID = @pDOCID
WHILE @a > 0
BEGIN
IF @i = 0
BEGIN
IF @PARENT_ID = 1
BEGIN
SET @RESULT = '\'
BREAK
END
ELSE
BEGIN
SET @DOCID = @PARENT_ID
SET @RESULT = '\'
END
END
ELSE
BEGIN
IF @PARENT_ID = 1
BEGIN
SET @RESULT = '\' + @PARENTNAME + @RESULT
BREAK
END
ELSE
BEGIN
SET @DOCID = @PARENT_ID
SET @RESULT = '\' + @PARENTNAME + @RESULT
END
END
--select * from [172.24.12.41\BRAINPOOL].windream60.dbo.BaseAttributes
SELECT @PARENTNAME = szLongName,@PARENT_ID = dwParentID FROM windream60.dbo.BaseAttributes WHERE dwDocID = @DOCID
SET @i = @i + 1
END
END
SET @RESULT = @WM_PREFIX + @RESULT + @DATEINAME
RETURN @RESULT
END
GO
CREATE VIEW [dbo].[VWPM_DOC_SEARCH] AS
SELECT TOP 100 PERCENT
T.dwDocID as DocID
,T.dwParentID
,dbo.FNDD_GET_WINDREAM_FILE_PATH (T.dwDocID) AS FULL_FILENAME
,(SELECT szLongName from windream60.dbo.BaseAttributes WHERE dwDocID = T.dwDocID) AS [Filename]
,T.szText00
,T.szText01
,T.szText02
,T.szText03
,T.szText04
,T.szText05
,T.szText06
,T.szText07
,T.szText08
,T.szText09
,T.szText10
,T.szText11
,T.szText12
,T.szText13
,T.szText14
,T.szText15
,T.szText16
,T.szText17
,T.szText18
,T.szText19
,T.szText20
,T.szText21
,T.szText22
,T.szText23
,T.szText24
,T.szText25
,T.szText26
,T.szText27
,T.szText28
,T.szText29
,T.szText30
,T.szText31
,T.szText32
,T.szText33
,T.szText34
,T.szText35
,ISNULL(T.szText36,'NO DOCTYPE') AS Doctype
,T.szText37
,T.szText38
,T.szText39
,T.dwInteger00
,T.dwInteger01
,T.dwInteger02
,T.dwInteger03
,T.dwInteger04
,T.dwInteger05
,T.dwInteger06
,T.dwInteger07
,T.dwInteger08
,T.dwInteger09
,T.dwInteger10
,T.dwInteger11
,T.dwInteger12
,T.dwInteger13
,T.dwInteger14
,T.dwInteger15
,T.dwInteger16
,T.dwInteger17
,T.dwInteger18
,T.dwInteger19
,T.dwInteger20
,T.dwInteger21
,T.dwInteger22
,T.dwInteger23
,T.dwInteger24
,T.lfFloat00
,T.lfFloat01
,T.lfFloat02
,T.lfFloat03
,T.lfFloat04
,T.lfFloat05
,T.lfFloat06
,T.lfFloat07
,T.lfFloat08
,T.lfFloat09
,T.lfFloat10
,T.lfFloat11
,T.lfFloat12
,T.lfFloat13
,T.lfFloat14
,T.blBool00
,T.blBool01
,T.blBool02
,T.blBool03
,T.blBool04
,T.dwDate00
,T.dwDate01
,T.dwDate02
,T.dwDate03
,T.dwDate04
,T.dwDate05
,T.dwDate06
,T.dwDate07
,T.dwDate08
,T.dwDate09
,T.wmVar00
,T.wmVar01
,T.wmVar02
,T.wmVar03
,T.wmVar04
,T.wmVar05
,T.wmVar06
,T.wmVar07
,T.wmVar08
,T.wmVar09
,T.wmVar10
,T.wmVar11
,T.wmVar12
,T.wmVar13
,T.wmVar14
,T.wmVar15
,T.wmVar16
,T.wmVar17
,T.wmVar18
,T.wmVar19
,T.wmVar20
,T.wmVar21
,T.wmVar22
,T.wmVar23
,T.wmVar24
,T.wmVar25
,T.wmVar26
,T.wmVar27
,T.wmVar28
,T.wmVar29
,(SELECT ISNULL(T.dwVersionNumber,'1') from windream60.dbo.BaseAttributes WHERE dwDocID = T.dwDocID) AS [Version]
,CAST(CAST(CONVERT(DATE,CONVERT(VARCHAR(10),T.dwCreationDate)) AS DATETIME) + CAST(STUFF(STUFF(REPLICATE('0',6-LEN(T.dwCreation_Time)) + convert(VARCHAR(6),T.dwCreation_Time),3,0,':'),6,0,':') AS DATETIME) AS DATETIME) AS [Creation_DateTime]
,CAST(CAST(CONVERT(DATE,CONVERT(VARCHAR(10),T.dwChangeDate)) AS DATETIME) + CAST(STUFF(STUFF(REPLICATE('0',6-LEN(T.dwChange_Time)) + convert(VARCHAR(6),T.dwChange_Time),3,0,':'),6,0,':') AS DATETIME) AS DATETIME) AS Change_DateTime,T1.szDocTypeName AS OBJECTTYPE
,T.dwObjectTypeID
FROM
windream60.dbo.BaseAttributes T
,windream60.dbo.ObjectType T1
,TBPM_PROFILE_FILES T2
WHERE
--T.dwParentID = 1896955 AND
T.dwCatalogID = 1
AND T.dwObjectTypeID = 4
AND T.dwObjectTypeID = T1.dwObjectTypeID
AND (T.dwDocID = T2.DOC_ID OR T.dwInteger23 = T2.DOC_ID)
ORDER BY [Creation_DateTime]
GO
CREATE FUNCTION [dbo].[FNDD_CHECK_USER_MODULE] (@pUSERNAME VARCHAR(100), @pMODULE_SHORT_NAME VARCHAR(10),@pCLIENTID INTEGER)
RETURNS @Table TABLE
(SequentialOrder INT IDENTITY(1, 1),
USER_ID INTEGER,
USER_PRENAME VARCHAR(50),
USER_SURNAME VARCHAR(50),
USER_SHORTNAME VARCHAR(50),
USER_EMAIL VARCHAR(100),
USER_LANGUAGE VARCHAR(10),
USER_DATE_FORMAT VARCHAR(10),
USER_RIGHT_FILE_DEL BIT,
MODULE_ACCESS BIT,
IS_ADMIN BIT,
USERCOUNT_LOGGED_IN INTEGER,
COMMENT VARCHAR(500))
AS
BEGIN
/*
This function checks all user-relevant relations an
*/
DECLARE
@RESULT VARCHAR(500),
@USER_ID INTEGER,
@USER_PRENAME VARCHAR(50),
@USER_SURNAME VARCHAR(50),
@USER_SHORTNAME VARCHAR(50),
@USER_EMAIL VARCHAR(50),
@USER_LANGUAGE VARCHAR(10),
@USER_DATE_FORMAT VARCHAR(10),
@IS_IN_MODULE BIT,
@IS_ADMIN BIT,
@USER_RIGHT_FILE_DEL BIT,
@USERCOUNT_LOGGED_IN INTEGER,
@MODULE_NAME VARCHAR(100),
@MODULE_GUID INTEGER,
@USER_GROUPNAME VARCHAR(100),
@ADMIN_GROUPNAME VARCHAR(100)
SET @USER_ID = 0
SET @IS_ADMIN = 0
SET @IS_IN_MODULE = 0
SET @USERCOUNT_LOGGED_IN = 0
SET @RESULT = ''
IF @pMODULE_SHORT_NAME = 'PM'
BEGIN
SET @USER_GROUPNAME = 'PM_USER'
SET @ADMIN_GROUPNAME = 'PM_ADMINS'
END
ELSE IF @pMODULE_SHORT_NAME = 'CW'
BEGIN
SET @USER_GROUPNAME = 'CW_USER'
SET @ADMIN_GROUPNAME = 'CW_ADMINS'
END
ELSE IF @pMODULE_SHORT_NAME = 'ADDI'
BEGIN
SET @USER_GROUPNAME = 'ADDI_USER'
SET @ADMIN_GROUPNAME = 'ADDI_ADMINS'
END
ELSE IF @pMODULE_SHORT_NAME = 'GLOBIX'
BEGIN
SET @USER_GROUPNAME = 'GLOBIX_USER'
SET @ADMIN_GROUPNAME = 'GLOBIX_ADMINS'
END
ELSE IF @pMODULE_SHORT_NAME = 'UM'
BEGIN
SET @USER_GROUPNAME = 'XXXX'
SET @ADMIN_GROUPNAME = 'UM_ADMINS'
END
SELECT @MODULE_GUID = GUID, @MODULE_NAME = NAME FROM TBDD_MODULES WHERE SHORT_NAME = @pMODULE_SHORT_NAME
IF NOT EXISTS(SELECT GUID FROM TBDD_USER WHERE UPPER(USERNAME) = UPPER(@pUSERNAME))
BEGIN
SET @RESULT = 'USER NOT CONFIGURED OR LISTED'
END
ELSE
BEGIN
SELECT @USER_ID = GUID,@USER_PRENAME = PRENAME,
@USER_SURNAME = NAME, @USER_SHORTNAME = SHORTNAME,@USER_EMAIL = EMAIL,@USER_LANGUAGE = LANGUAGE,@USER_DATE_FORMAT = DATE_FORMAT FROM TBDD_USER WHERE UPPER(USERNAME) = UPPER(@pUSERNAME)
SELECT @USERCOUNT_LOGGED_IN = COUNT(*) FROM TBDD_USER_MODULE_LOG_IN WHERE UPPER(MODULE) = UPPER(@MODULE_NAME) AND CLIENT_ID = @pCLIENTID
--CHECK USER ÍS IN MODULE_USER_GROUP
IF EXISTS(select T1.* from TBDD_GROUPS T, TBDD_GROUPS_USER T1 WHERE T.GUID = T1.GROUP_ID AND T1.USER_ID = @USER_ID AND UPPER(T.NAME) = @USER_GROUPNAME)
BEGIN
SET @IS_IN_MODULE = 1
SET @RESULT = 'User is part of Group (' + @USER_GROUPNAME + ')'
IF EXISTS(select T.* from TBDD_USER_MODULES T WHERE T.USER_ID = @USER_ID AND T.MODULE_ID = @MODULE_GUID)
BEGIN
SET @RESULT = @RESULT + '| User is also configured in User-Modules'
select @IS_ADMIN = T.IS_ADMIN,@USER_RIGHT_FILE_DEL = T.RIGHT1 from TBDD_USER_MODULES T WHERE T.USER_ID = @USER_ID AND T.MODULE_ID = @MODULE_GUID
END
END
ELSE
BEGIN
SET @RESULT = 'User not part of group (' + @USER_GROUPNAME + ')'
IF EXISTS(select T.* from TBDD_USER_MODULES T WHERE T.USER_ID = @USER_ID AND T.MODULE_ID = @MODULE_GUID)
BEGIN
SET @RESULT = @RESULT + '| BUT User configured in User-Modules'
select @IS_ADMIN = T.IS_ADMIN,@USER_RIGHT_FILE_DEL = T.RIGHT1 from TBDD_USER_MODULES T WHERE T.USER_ID = @USER_ID AND T.MODULE_ID = @MODULE_GUID
END
END
IF EXISTS(select T1.* from TBDD_GROUPS T, TBDD_GROUPS_USER T1 WHERE T.GUID = T1.GROUP_ID AND T1.USER_ID = @USER_ID AND UPPER(T.NAME) = @ADMIN_GROUPNAME)
BEGIN
SET @RESULT = @RESULT + '| User is part of group (' + @ADMIN_GROUPNAME + ')'
SET @IS_ADMIN = 1
SET @IS_IN_MODULE = 1
END
END
INSERT INTO @Table (USER_ID,USER_PRENAME, USER_SURNAME,USER_SHORTNAME,USER_EMAIL,USER_LANGUAGE,USER_DATE_FORMAT, USER_RIGHT_FILE_DEL, MODULE_ACCESS,IS_ADMIN,USERCOUNT_LOGGED_IN, COMMENT)
VALUES (@USER_ID,@USER_PRENAME,@USER_SURNAME,@USER_SHORTNAME,@USER_EMAIL,@USER_LANGUAGE,@USER_DATE_FORMAT,@USER_RIGHT_FILE_DEL,@IS_IN_MODULE,@IS_ADMIN,@USERCOUNT_LOGGED_IN,@RESULT)
RETURN
END
GO
CREATE PROCEDURE [dbo].[PRPM_DELETE_PROFILE](@pPID INT)
AS
delete from TBPM_CONTROL_TABLE where CONTROL_ID in (SELECT GUID FROM TBPM_PROFILE_CONTROLS where PROFIL_ID = @pPID)
DELETE FROM TBPM_ERROR_LOG WHERE PROFIL_ID = @pPID
DELETE FROM TBPM_PROFILE_FILES WHERE PROFIL_ID = @pPID
DELETE FROM TBPM_PROFILE_FINAL_INDEXING WHERE PROFIL_ID = @pPID
DELETE FROM TBPM_PROFILE_CONTROLS WHERE PROFIL_ID = @pPID
DELETE FROM TBPM_PROFILE_USER WHERE PROFIL_ID = @pPID
DELETE FROM TBPM_PROFILE_GROUP WHERE PROFIL_ID = @pPID
DELETE FROM TBPM_PROFILE WHERE GUID = @pPID
GO
CREATE FUNCTION [dbo].[FNPM_GET_WM_FILE_PATH] (@pDOCGUID BIGINT,@STANDARD As INT = 0)
RETURNS VARCHAR(MAX)
AS
BEGIN
DECLARE @RELPATH VARCHAR(100),@FILEPATH VARCHAR(500),@NAVPATH as VARCHAR(MAX)
IF @STANDARD = 1
SET @RELPATH = '\\windeam\objects'
ELSE
SELECT @RELPATH = WM_REL_PATH FROM TBPM_KONFIGURATION WHERE GUID = 1
SELECT @FILEPATH = REPLACE(FILE_PATH,'W:\','') FROM TBPM_PROFILE_FILES WHERE (GUID = @pDOCGUID)
SET @NAVPATH = @RELPATH + '\' + @FILEPATH
RETURN @NAVPATH
END
GO