@ECHO Off & SETLOCAL
CHCP 1252

TITLE DIGITAL DATA - AlteSicherungenEntfernen

ECHO Stapelverarbeitungsprogramm
ECHO Alte Sicherungen Entfernen
ECHO -
ECHO Digital Data
ECHO Ludwig-Rinn-Strasse 16
ECHO 35452 Heuchelheim
ECHO Tel.: 0641 / 202360
ECHO E-Mail: info@didalog.de
ECHO -
ECHO Version 1.0
ECHO Letzte Aktualisierung: 11.04.2014
ECHO -
ECHO Programmstart am %date% um %time:~0,8% Uhr auf %computername%.

REM --------------------------------------------------------------
REM -------------------Definition der Variablen-------------------
REM --------------------------------------------------------------

SET SicherungsDateien=mrimg
    REM Dateiendung der Sicherungsdateien.

SET SicherungsMethode=0
    REM Wert 0 = SicherungsPfad ist ein lokales Laufwerk.
    REM Wert 1 = SicherungsPfad ist ein Netzwerk Laufwerk.

SET SicherungsLaufwerk=S:
    REM Laufwerksbuchstabe der verbunden werden soll z.B.: "S:".

SET SicherungsPfad=Macrium_Images
    REM Lokaler oder Netzwerkpfad ohne Laufwerksbuchstaben.

SET LaufwerksBenutzer=
    REM Anmeldenname für Netzwerkpfad <DOMÄNE\Benutzername>.

SET LaufwerksPasswort=
    REM Passwort für oben stehenden Anmeldenamen (unverschlüsselt).

SET Aufbewahrungszeit=6
    REM Anzahl wie viele Tage die Dateien behalten werden sollen.

REM --------------------------------------------------------------

IF %SicherungsMethode%==0 (ECHO Ein lokales Laufwerk wird verwendet.) && (GOTO Programm1)
IF %SicherungsMethode%==1 (ECHO Ein Netzwerk Laufwerk wird verwendet.)

ECHO -
ECHO Beginne Laufwerksmapping (CMD Befehl forfiles arbeitet nicht mit UNC Pfaden).
IF EXIST %SicherungsLaufwerk% (net use %SicherungsLaufwerk% /delete /yes)
net use %SicherungsLaufwerk% %SicherungsPfad%  %LaufwerksPasswort% /user:%LaufwerksBenutzer%

:Programm1

REM --------------------------------------------------------------
REM --------------------Programm / Skript 1-----------------------
REM --------------------------------------------------------------

ECHO -
ECHO Folgende alte Datensicherungen wurden gefunden:
%windir%\System32\forfiles /P "%SicherungsLaufwerk%\%SicherungsPfad%" /M *.%SicherungsDateien% /S /D -%Aufbewahrungszeit%
IF %ERRORLEVEL% == 1 (ECHO Es existieren aktuell keine zu entfernenden Datensicherungen.) && (GOTO Abschlussarbeiten)

ECHO -
ECHO Entferne nun aufgelistete Datensicherungen.
%windir%\System32\forfiles /P "%SicherungsLaufwerk%\%SicherungsPfad%" /M *.%SicherungsDateien% /S /C "cmd /c if @isdir==FALSE del @file" /D -%Aufbewahrungszeit%
IF %ERRORLEVEL% == 0 (ECHO Datensicherungen wurden erfolgreich entfernt.)
IF %ERRORLEVEL% == 1 (ECHO Es ist ein Fehler waehrend der Abarbeitung aufgetreten.)

REM --------------------------------------------------------------

:Abschlussarbeiten

ECHO -
IF %SicherungsMethode%==0 (ECHO Ein lokales Laufwerk wurde verwendet.) && (GOTO exit)
IF %SicherungsMethode%==1 (ECHO Ein Netzwerk Laufwerk wurde verwendet.)

ECHO -
ECHO Laufwerksmapping wird wieder entfernt.
net use %SicherungsLaufwerk% /delete /yes

:exit

ECHO -
ECHO Alle Aufgaben wurden abgeschlossen. 
ECHO Das Programm wird beendet.
CHCP 850
exit