Anlage des Repos

2024-01-24 16:42:38 +01:00
commit 38d6a271c4
1785 changed files with 3051496 additions and 0 deletions
--- a/current/Modules/Archiv/Packtisch/ArticleExists.vbs
+++ b/current/Modules/Archiv/Packtisch/ArticleExists.vbs
@@ -0,0 +1,135 @@
+' ArticleExists(Identifier: String)
+' ---------------------------------------------------------
+' Findet Artikelnummer anhand von versch. Kriterien
+' - Artikel-Nummer, Alternative Artikel-Nummer, EAN-Code, Seriennummer
+' - Gibt die Zeile im Grid zurück in der Artikel das erste Mal gefunden wurde
+' 
+' Rückgabewert: ArticleRow: Int
+' ---------------------------------------------------------
+
+Const ARTICLE_EXISTS_NO_STOCK = -99
+Const ARTICLE_EXISTS_NO_SERIALNUMBER = -98
+Const ARTICLE_EXISTS_NO_ARTICLE_EAN = -97
+
+Function ArticleExists(Identifier)
+	ArticleExists = 0
+	CURRENT_SERIALNUMBER = ""
+		
+	Set mywin = CWLStart.CurrentModule.Windows.Item(WINDOW_ID)
+	Set Grid = mywin.Controls.Item(GRID_ID).Grid
+	
+	' ===================== ARTIKEL NUMMER / EAN-CODE =====================
+	SQL = ""
+	' Artikelnummer / EAN-Code / Alternative Artikelnummer
+	SQL = SQL & "((C002 = '" & Identifier & "') Or (C075 = '" & Identifier & "') Or (C114 = '" & Identifier & "')) AND "
+	' Artikel darf nicht inaktiv sein
+	SQL = SQL & "(c038 IS NULL) "
+	' Nach Mandant und Wirtschaftsjahr filtern
+	SQL = SQL & SQLQuery_BasicWhere
+	
+	Set ResultArtikel = CWLStart.CurrentCompany.SearchRecord(TABLE_21, SQL)
+	
+	If DEBUG_ON = True Then
+		AddDebugLine "Searching for Article by ArticleNo/EAN-Code.. " & vbNewline & vbNewline
+		AddDebugLine "Result Columns: " & ResultArtikel & vbNewline
+		AddDebugLine "Result Rows: " & ResultArtikel.RowCount & vbNewline
+		AddDebugLine "SQL: " & SQL
+		
+		ShowDebugBox "ArticleExists"
+	End If
+	
+	' ===================== SERIENNUMMER =====================
+	SQL = ""
+	' Artikelnummer
+	SQL = SQL & "(C068 = '" & Identifier & "') AND "
+	' Artikel darf nicht inaktiv sein
+	SQL = SQL & "(c038 IS NULL) "
+	' Nach Mandant und Wirtschaftsjahr filtern
+	SQL = SQL & SQLQuery_BasicWhere
+	
+	Set ResultSeriennummer = CWLStart.CurrentCompany.SearchRecord(TABLE_21, SQL)
+	
+	If DEBUG_ON = True Then
+		AddDebugLine "Searching for Article by Article serial number " & vbNewline & vbNewline
+		AddDebugLine "Result Columns: " & ResultSeriennummer & vbNewline
+		AddDebugLine "Result Rows: " & ResultSeriennummer.RowCount & vbNewline
+		AddDebugLine "SQL: " & SQL
+		
+		ShowDebugBox "ArticleExists"
+	End If
+	
+	If ResultSeriennummer.RowCount > 0 Then
+		CURRENT_SERIALNUMBER = Identifier
+		Set Result = ResultSeriennummer	
+	Else
+		Set Result = ResultArtikel
+	End If
+	
+	'==========================================================
+	If Result.RowCount > 0 Then
+		' Wir brauchen die Hauptartikelnummer, weil die Prüfung sonst bei SN-Artikeln fehlschlägt
+		MainArticleNumber = Result.Value("C011")
+		RealArticleNumber = Result.Value("C002")
+		
+		' Lagerstand des Artikels prüfen
+		SQL = ""
+		SQL = SQL & "SELECT "
+		SQL = SQL & "(SELECT C008 AS [MengeZugang] from [v021] (NOLOCK) where (c011 = '__ARTICLENUMBER__' OR c002 = '__ARTICLENUMBER__') "& SQLQuery_BasicWhere &") - "
+		SQL = SQL & "(SELECT C009 AS [MengeAbgang] from [v021] (NOLOCK) where (c011 = '__ARTICLENUMBER__' OR c002 = '__ARTICLENUMBER__') "& SQLQuery_BasicWhere &") - "
+		SQL = SQL & "ISNULL((SELECT SUM(C035) AS [MengeVerkauf] FROM [t014] (NOLOCK) where c000 = '__ARTICLENUMBER__' "& SQLQuery_BasicWhere &"), 0) AS c000"
+		
+		SQL = Replace(SQL, "__ARTICLENUMBER__", RealArticleNumber)
+		
+		Set Result = CWLStart.CurrentCompany.Connection.Select(SQL)
+		AmountStocked = Result.Value("c000")
+		
+		If DEBUG_ON = True Then
+			AddDebugLine "Checking stock of product: " & RealArticleNumber & " (" & MainArticleNumber & ")" & vbNewline & vbNewline
+			AddDebugLine "Result Columns: " & Result & vbNewline
+			AddDebugLine "Result Rows: " & Result.RowCount & vbNewline
+			AddDebugLine "Stock: " & AmountStocked & vbNewLine
+			AddDebugLine "SQL: " & SQL
+			
+			ShowDebugBox "ArticleExists"
+		End If
+		
+		If AmountStocked > 0 Then
+			If DEBUG_ON = True Then
+				AddDebugLine "Amount stocked: " & AmountStocked
+				ShowDebugBox "ArticleExists"
+			End If
+			
+			' Vorkommen in Tabelle prüfen
+			For Row = 1 To Grid.LineCount
+				CurrentArticleNumber = Grid.GetCellValue(Row, COLUMN_ARTICLENUMBER)
+				Total = Cint(Grid.GetCellValue(Row, COLUMN_TOTAL))
+				Scanned = Cint(Grid.GetCellValue(Row, COLUMN_SCANNED))
+				
+				If CurrentArticleNumber = MainArticleNumber Then
+					If DEBUG_ON = True Then
+						AddDebugLine "CurrentArticleNumber matches MainArticleNumber! (" & CurrentArticleNumber & ")"
+						ShowDebugBox "ArticleExists"
+					End If
+				
+					If Total > Scanned Then
+						If DEBUG_ON = True Then
+							AddDebugLine "Product is not yet scanned completetly and exists in Row " & Row & "!"
+							ShowDebugBox "ArticleExists"
+						End If
+					
+						ArticleExists = Row
+						Exit For
+					End If
+				End If
+			Next
+		Else
+			ArticleExists = ARTICLE_EXISTS_NO_STOCK
+		End If	
+	Else
+		If CURRENT_SERIALNUMBER = "" Then
+			ArticleExists = ARTICLE_EXISTS_NO_ARTICLE_EAN
+		Else
+			ArticleExists = ARTICLE_EXISTS_NO_SERIALNUMBER
+		End If
+	End If
+End Function
--- a/current/Modules/Archiv/Packtisch/CompleteOrder.vbs
+++ b/current/Modules/Archiv/Packtisch/CompleteOrder.vbs
@@ -0,0 +1,199 @@
+' CompleteOrder()
+' ---------------------------------------------------------
+' Schließt die Prüfung ab und erstellt einen Lieferschein
+' 
+' Rückgabewert: Keiner
+' ---------------------------------------------------------
+Sub CompleteOrder()
+	Set mywin = CWLStart.CurrentModule.Windows.Item(WINDOW_ID)
+	Set Conn = CWLStart.CurrentCompany.Connection
+	Set Grid = mywin.Controls.Item(GRID_ID).Grid
+	
+	Dim OrderId, AccountSQL, MandatorId, RunningNumber
+	
+	
+	OrderId = mywin.Controls.Item(ORDER_INPUT).ScreenContents
+	AccountSQL = "SELECT DISTINCT c021 FROM t025 (NOLOCK) WHERE c044 = '" & OrderId & "' " & SQLQuery_BasicWhere
+	
+	Set AccountResult = Connection.Select(AccountSQL)
+	
+	If DEBUG_ON = True Then
+		AddDebugLine "Querying for CustomerAccountId.. " & vbNewline
+		AddDebugLine "Result Columns: " & AccountResult
+		AddDebugLine "Result Rows: " & AccountResult.RowCount
+		AddDebugLine "SQL: " & AccountSQL
+		
+		ShowDebugBox "CompleteOrder"
+	End If
+	
+	MandatorId = AccountResult.Value("c021")
+	RunningNumber = RUNNING_NUMBER_PREFIX & OrderId
+	BelegKey = Cstr(DateDiff("s", "01/01/1970 00:00:00", Now))
+	
+	' ===================== KOPFDATEN =====================
+	
+	HeadSQL = "INSERT INTO " & SQLDB_for_EXIM & "." & SQLHeadTB_for_EXIM & " "
+	HeadSQL = HeadSQL & "(BELEGKEY, Kontonummer, Laufnummer, Auftragsnummer, Datum_Lieferschein) "
+	HeadSQL = HeadSQL & "VALUES("& BelegKey &", '"& MandatorId &"', '"& RunningNumber &"', '"& OrderId &"', GETDATE())"
+	
+	HeadResult = Conn.ExecuteSQL(HeadSQL)
+	
+	If DEBUG_ON = True Then
+		AddDebugLine "Inserting Head Data" & vbNewline
+		AddDebugLine "Result: " & HeadResult
+		AddDebugLine "SQL: " & HeadSQL
+		
+		ShowDebugBox "CompleteOrder"
+	End If
+	
+	' ===================== ENDE KOPFDATEN =====================
+
+	' ===================== MITTEDATEN =====================
+	
+	Dim ArticleNumber, AmountDelivered, SerialNumber, StorageLocation, LineNumber
+	
+	For Row = 1 To Grid.LineCount
+		IsSerialNumberArticle = Grid.GetCellValue(Row, COLUMN_TYPE)
+		ArticleNumber = Grid.GetCellValue(Row, COLUMN_ARTICLENUMBER)
+		SerialNumber = Grid.GetCellValue(Row, COLUMN_SERIALNUMBER)	
+		LineNumber = GetWinLineOriginalLineNumber(OrderId, ArticleNumber, IsSerialNumberArticle)
+		StorageLocation = GetWinLineStorageLocation(ArticleNumber, SerialNumber, IsSerialNumberArticle)		
+		AmountDelivered = Grid.GetCellValue(Row, COLUMN_SCANNED)
+		
+		If IsSerialNumberArticle = 1 Then
+			MidSQL = "INSERT INTO " & SQLDB_for_EXIM & "." & SQLMiddleTB_for_EXIM & " "
+			MidSQL = MidSQL & "(BELEGKEY, Artikelnummer, Hauptartikelnummer, Zeilennummer, Datentyp, Mengegeliefert, ChargeIdentnummer, Lagerort) "
+			MidSQL = MidSQL & "VALUES("& BelegKey &", '"& ArticleNumber &"', '"& ArticleNumber &"', "& LineNumber &", '1', "& AmountDelivered &", '"& SerialNumber &"', "& StorageLocation &")"
+		Else
+			MidSQL = "INSERT INTO " & SQLDB_for_EXIM & "." & SQLMiddleTB_for_EXIM & " "
+			MidSQL = MidSQL & "(BELEGKEY, Artikelnummer, Hauptartikelnummer, Zeilennummer, Datentyp, Mengegeliefert, ChargeIdentnummer, Lagerort) "
+			MidSQL = MidSQL & "VALUES("& BelegKey &", '"& ArticleNumber &"', '"& ArticleNumber &"', NULL, '1', "& AmountDelivered &", '"& SerialNumber &"', "& StorageLocation &")"
+		End If
+
+		MidResult = Conn.ExecuteSQL(MidSQL)
+		
+		If DEBUG_ON = True Then
+			AddDebugLine "Inserting Middle Data" & vbNewline
+			AddDebugLine "Result: " & MidResult
+			AddDebugLine "SQL: " & MidSQL
+			
+			ShowDebugBox "CompleteOrder"
+		End If	
+	Next
+	
+	' ===================== ENDE MITTEDATEN =====================
+
+	' ============================ XML ============================
+	Dim Request, URL, XML
+	Dim DObj : DObj = Now
+	Dim DateString : DateString = Year(DObj) & "-" & GetLeftPad(Month(DObj)) & "-" & GetLeftPad(Day(DObj))
+	
+	XML = ""
+	XML = XML & "<?xml version=""1.0"" encoding=""UTF-8""?>"
+	XML = XML & "<MESOWebService TemplateType=""__TYPE__"" Template=""__VORLAGE__"" option=""__OPTION__"" printVoucher=""__PRINT__"">"
+	
+	' Kopf
+	XML = XML & "<__VORLAGE__T025>"	
+		XML = XML & "<BELEGKEY>" & BelegKey & "</BELEGKEY>"
+		XML = XML & "<Kontonummer>" & MandatorId & "</Kontonummer>"
+		XML = XML & "<Laufnummer>" & RunningNumber & "</Laufnummer>"
+		XML = XML & "<Auftragsnummer>" & OrderId & "</Auftragsnummer>"
+		XML = XML & "<Datum_Lieferschein>" & DateString & "</Datum_Lieferschein>"
+	XML = XML & "</__VORLAGE__T025>"
+	
+	For Row = 1 To Grid.LineCount
+	
+		ArticleNumber = Grid.GetCellValue(Row, COLUMN_ARTICLENUMBER)
+		SerialNumber = Grid.GetCellValue(Row, COLUMN_SERIALNUMBER)	
+		LineNumber = GetWinLineOriginalLineNumber(OrderId, ArticleNumber, IsSerialNumberArticle)
+		StorageLocation = GetWinLineStorageLocation(ArticleNumber, SerialNumber, IsSerialNumberArticle)
+		AmountDelivered = Grid.GetCellValue(Row, COLUMN_SCANNED)
+		InternalArticleNumber = GetWinLineInternalProductNumber(ArticleNumber, SerialNumber)
+				
+		' Mitte
+		MidXML = ""
+		MidXML = MidXML & "<__VORLAGE__T026>"
+			MidXML = MidXML & "<BELEGKEY>" & BelegKey & "</BELEGKEY>"
+			MidXML = MidXML & "<Artikelnummer>" & InternalArticleNumber & "</Artikelnummer>"
+			MidXML = MidXML & "<Hauptartikelnummer>" & ArticleNumber & "</Hauptartikelnummer>"
+			MidXML = MidXML & "<Zeilennummer>" & LineNumber & "</Zeilennummer>"
+			MidXML = MidXML & "<Datentyp>" & "1" & "</Datentyp>"
+			MidXML = MidXML & "<Mengegeliefert>" & AmountDelivered & "</Mengegeliefert>"
+			MidXML = MidXML & "<ChargeIdentnummer>" & SerialNumber & "</ChargeIdentnummer>"
+			MidXML = MidXML & "<Lagerort>" & StorageLocation & "</Lagerort>"
+		MidXML = MidXML & "</__VORLAGE__T026>"
+			
+		If DEBUG_ON = True Then
+			AddDebugLine "Adding Product Row to XML:" & vbNewLine
+			AddDebugLine MidXML
+			
+			ShowDebugBox "CompleteOrder"	
+		End If
+	
+		XML = XML & MidXML
+	Next
+	
+	XML = XML & "</MESOWebService>"
+	XML = Replace(XML, "__VORLAGE__", WEB_VORLAGE)
+	XML = Replace(XML, "__TYPE__", WEB_TYPE)
+	XML = Replace(XML, "__OPTION__", WEB_OPTION)
+	XML = Replace(XML, "__PRINT__", WEB_PRINT)
+	
+	URL = "http://__SERVER__/ewlservice/import?User=__USER__&Password=__PASSWORD__&Company=__COMPANY__&Type=30&Vorlage=__VORLAGE__&Actioncode=__ACTIONCODE__&byref=0&Data=__DATA__"
+	URL = Replace(URL, "__SERVER__", WEB_SERVER)
+	URL = Replace(URL, "__USER__", WEB_USER)
+	URL = Replace(URL, "__PASSWORD__", WEB_PASS)
+	URL = Replace(URL, "__COMPANY__", WEB_COMPANY)
+	URL = Replace(URL, "__VORLAGE__", WEB_VORLAGE)
+	URL = Replace(URL, "__ACTIONCODE__", WEB_ACTIONCODE)
+	URL = Replace(URL, "__DATA__", XML)
+	
+	If DEBUG_ON = True Then
+		AddDebugLine "Sending Request to WebServices.."
+		AddDebugLine "URL: " & URL
+		
+		ShowDebugBox "CompleteOrder"
+	End If
+	
+	' ======================= ENDE XML =======================
+	
+	' ===================== HTTP REQUEST =====================
+	
+	Set Request = CreateObject("MSXML2.XMLHTTP")
+	Request.Open "POST", URL, False
+	Request.Send
+	Response = Request.ResponseText
+	Status = Request.Status
+	
+	If DEBUG_ON = True Then
+		AddDebugLine "Response from WebServices!"
+		AddDebugLine "Status: " & Status
+		AddDebugLine "Body: " & Response
+		
+		ShowDebugBox "CompleteOrder"
+	End If
+	
+	' =================== ENDE HTTP REQUEST ==================
+
+	Error = False
+	Message = ""
+	
+	If Status = 200 Then
+		If InStr(Response, "<OverallSuccess>true</OverallSuccess>") > 0 Then
+			Message = "Lieferschein wurde übertragen!"
+		Else
+			Error = True
+			Message = "Lieferschein wurde nicht übertragen! Fehlerdetails: " & vbNewline & vbNewline & Response
+		End	If
+	Else
+		Error = True
+		Message = "Fehler beim Zugriff auf Webservices aufgetreten" & vbNewline & "Status: " & Status
+	End If
+	
+	If Error = False Then
+		MsgBox Message, vbInformation, DEFAULT_TITLE & " - Abschluss erfolgreich"
+		MacroCommands.MSetFieldFocus WINDOW_ID, ORDER_INPUT
+	Else
+		MsgBox Message, vbExclamation, DEFAULT_TITLE & " - Fehler bei Abschluss"
+	End If
+End Sub
--- a/current/Modules/Archiv/Packtisch/IsOrderAvailable.vbs
+++ b/current/Modules/Archiv/Packtisch/IsOrderAvailable.vbs
@@ -0,0 +1,47 @@
+' IsOrderAvailable()
+' ---------------------------------------------------------
+' Überprüft, ob Auftrag noch (teilweise) offen ist
+' 
+' Rückgabewert: OrderAvailable: Boolean
+' ---------------------------------------------------------
+Function IsOrderAvailable(OrderNumber)
+	Set mywin = CWLStart.CurrentModule.Windows.Item(WINDOW_ID)
+	Set Grid = mywin.Controls.Item(GRID_ID).Grid
+	
+	IsOrderAvailable = False
+	
+	SQL = ""
+	SQL = SQL & "(c044 = '"& OrderNumber &"')"
+	SQL = SQL & "AND (c025 IN ('M', 'A', 'S'))"
+	SQL = SQL & SQLQuery_BasicWhere
+
+	Set Result = CWLStart.CurrentCompany.SearchRecord(TABLE_25, SQL)
+
+	If DEBUG_ON = True Then
+		MsgBox "SQL: ... FROM "& TABLE_25 & " WHERE " & SQL, vbOkonly, DEBUG_TITLE
+		
+		AddDebugLine "Checking For Order by OrderId.." & vbNewline & vbNewline
+		AddDebugLine "Result Columns: " & Result & vbNewline
+		AddDebugLine "Result Rows: " & Result.RowCount & vbNewline
+		AddDebugLine "SQL: " & SQL
+	
+		ShowDebugBox "IsOrderAvailable"
+	End If
+
+	If Result < 0 Then
+		If err <> 0 Then
+			Msgbox "Fehler bei Abfrage:" & vbNewline & err.description, vbExclamation, DEFAULT_TITLE & " - IsOrderAvailable"
+			Exit Function
+		Else
+			Msgbox "Der Auftrag " & _
+					OrderNumber & _
+					" wurde bereits vollständig erledigt oder als abgeschlossen markiert!", _
+					vbExclamation, DEFAULT_TITLE & " - IsOrderAvailable"
+			Exit Function
+		End If
+	End If
+
+	If Result.RowCount > 0 Then
+		IsOrderAvailable = True
+	End If
+End Function
--- a/current/Modules/Archiv/Packtisch/IsOrderComplete.vbs
+++ b/current/Modules/Archiv/Packtisch/IsOrderComplete.vbs
@@ -0,0 +1,22 @@
+' IsOrderComplete()
+' ---------------------------------------------------------
+' Überprüft, ob alle Zeilen vollständig gescannt wurden
+' 
+' Rückgabewert: OrderComplete: Boolean
+' ---------------------------------------------------------
+Function IsOrderComplete()
+	Set mywin = CWLStart.CurrentModule.Windows.Item(WINDOW_ID)
+	Set Grid = mywin.Controls.Item(GRID_ID).Grid
+	
+	IsOrderComplete = True
+	
+	For Row = 1 To Grid.LineCount
+		Total = Cint(Grid.GetCellValue(Row, COLUMN_TOTAL))
+		Scanned = Cint(Grid.GetCellValue(Row, COLUMN_SCANNED))
+		
+		If Scanned < Total Then
+			IsOrderComplete = False
+			Exit For
+		End If
+	Next
+End Function
--- a/current/Modules/Archiv/Packtisch/LoadOrder.vbs
+++ b/current/Modules/Archiv/Packtisch/LoadOrder.vbs
@@ -0,0 +1,111 @@
+' LoadOrder(OrderNumber: String)
+' ---------------------------------------------------------
+' Sucht Belegzeilen zur angegebenen Belegnummer
+' - Filtert Artikel der Gruppe 100 aus
+' - Lädt Ergebnisse in eine Tabelle auf dem Formular
+' - Erzeugt N Zeilen für Seriennummer-Artikel der Menge N
+' 
+' Rückgabewert: LoadSuccessful: Boolean
+' ---------------------------------------------------------
+Function LoadOrder(OrderNumber)
+	Set mywin = CWLStart.CurrentModule.Windows.Item(WINDOW_ID)
+	Set Grid = mywin.Controls.Item(GRID_ID).Grid
+	
+	' ARTIKEL FILTERN
+	SQL = ""
+	' Nach eingescannter Auftragsnummer/Belegnummer filtern
+	SQL = SQL & "(c067 = '"& OrderNumber &"') "
+	' Versandkosten (Art.Gruppe 100) rausfiltern
+	SQL = SQL & "and c012 NOT IN (100) "
+	' Nur Artikel aus offenen Belegen anzeigen
+	SQL = SQL & "and c031 = c112"
+	' Nach Mandant und Wirtschaftsjahr filtern
+	SQL = SQL & SQLQuery_BasicWhere
+		
+	Set Result = CWLStart.CurrentCompany.SearchRecord (TABLE_26, SQL)
+	
+	If DEBUG_ON = True Then
+		MsgBox "SQL: ... FROM "& TABLE_26 & " WHERE " & SQL, vbOkonly, DEBUG_TITLE
+		
+		AddDebugLine "Searching For Order by OrderId.." & vbNewline & vbNewline
+		AddDebugLine "Result Columns: " & Result & vbNewline
+		AddDebugLine "Result Rows: " & Result.RowCount & vbNewline
+		AddDebugLine "SQL: " & SQL
+	
+		ShowDebugBox "LoadOrder"
+	End If
+	
+	If Result < 0 Then
+		If err <> 0 Then
+			Msgbox "Fehler bei Abfrage:" & vbNewline & err.description, vbExclamation, DEFAULT_TITLE & " - LoadOrder"
+			Exit Function
+		Else
+			Msgbox "Abfrage lieferte keine Ergebnisse.", vbExclamation, DEFAULT_TITLE & " - LoadOrder"
+			Exit Function
+		End If
+	End If
+	
+	Grid.InitUserGrid
+	Grid.Header
+	Grid.Clear(1002)
+	Grid.IsRedraw = False
+	
+	If Result.RowCount > 0 Then
+		LineCounter = 1
+		
+		' Speicher für benutzerdefinierte Felder
+		' (495,0) - Menge Gescannt
+		' (495,1) - Menge Gesamt
+		' (495,2) - Seriennummer
+		' (495,3) - Artikelnummer
+		' (495,4) - Bezeichnung
+
+		Do
+			' Zeilen hochzählen		
+			Amount = Cint(Result.Value("c005"))
+			ChargeFlag = Cint(Result.Value("c055"))
+			
+			If ChargeFlag = 2 Then
+				For index = 1 To Amount
+					CWLCurrentWindow.ActiveWindow.Vars.Value(495,0) = 1
+					CWLCurrentWindow.ActiveWindow.Vars.Value(495,1) = 0
+					CWLCurrentWindow.ActiveWindow.Vars.Value(495,2) = ""	
+					CWLCurrentWindow.ActiveWindow.Vars.Value(495,3) = Result.Value("c003")
+					CWLCurrentWindow.ActiveWindow.Vars.Value(495,4) = Result.Value("c004")
+					CWLCurrentWindow.ActiveWindow.Vars.Value(495,5) = 1
+					Grid.AddLine
+					
+					' Zeilenfarbe mit ROT vorbelegen
+					Grid.SetLineColor LineCounter, COLOR_RED
+					
+					LineCounter = LineCounter + 1
+				Next
+			Else
+				CWLCurrentWindow.ActiveWindow.Vars.Value(495,0) = Cint(Result.Value("c005"))
+				CWLCurrentWindow.ActiveWindow.Vars.Value(495,1) = 0
+				CWLCurrentWindow.ActiveWindow.Vars.Value(495,2) = ""	
+				CWLCurrentWindow.ActiveWindow.Vars.Value(495,3) = Result.Value("c003")
+				CWLCurrentWindow.ActiveWindow.Vars.Value(495,4) = Result.Value("c004")
+				CWLCurrentWindow.ActiveWindow.Vars.Value(495,5) = 0
+				
+				' Ergebnisse aus SQL in Zeile schreiben	
+				Grid.AddLine
+				
+				' Zeilenfarbe mit ROT vorbelegen
+				Grid.SetLineColor LineCounter, COLOR_RED
+				
+				LineCounter = LineCounter + 1
+			End If		
+			
+			If Result.NextRecord = False Then
+				Exit Do
+			End If
+		Loop
+		LoadOrder = True
+	Else
+		MsgBox "Auftrag wurde bereits bearbeitet oder existiert nicht", vbExclamation, DEFAULT_TITLE
+		LoadOrder = False
+	End If
+		
+	Grid.IsRedraw = True
+End Function
--- a/current/Modules/Archiv/Packtisch/SerialNumberExists.vbs
+++ b/current/Modules/Archiv/Packtisch/SerialNumberExists.vbs
@@ -0,0 +1,20 @@
+Function SerialNumberExists(SerialNumber)
+	Set mywin = CWLStart.CurrentModule.Windows.Item(WINDOW_ID)
+	Set Grid = mywin.Controls.Item(GRID_ID).Grid
+	
+	SerialNumberExists = False
+	
+	If DEBUG_ON = True Then
+		AddDebugLine "Checking existence of SerialNumber: " & SerialNumber
+		ShowDebugBox "SerialNumberExists"
+	End If
+	
+	For Row = 1 To Grid.LineCount
+		CurrentSerialNumber = Grid.GetCellValue(Row, COLUMN_SERIALNUMBER)
+		
+		If SerialNumber = CurrentSerialNumber Then
+			SerialNumberExists = True
+			Exit For
+		End If
+	Next
+End Function
--- a/current/Modules/Archiv/Packtisch/SetAmount.vbs
+++ b/current/Modules/Archiv/Packtisch/SetAmount.vbs
@@ -0,0 +1,18 @@
+' SetAmount(Amount: Integer)
+' ---------------------------------------------------------
+' Setzt eigegeben Menge in das Mengenfeld
+' - Überschreibt Menge beim ersten Eintrag, danach
+'   wird die Zahl angehängt
+' 
+' Rückgabewert: Keiner
+' ---------------------------------------------------------
+Sub SetAmount(Amount)
+	Set mywin = CWLStart.CurrentModule.Windows.Item(WINDOW_ID)
+	Set amountBox = mywin.Controls.Item(AMOUNT_INPUT)
+	
+	If amountBox.Contents = AMOUNT_PLACEHOLDER Then
+		amountBox.Contents = Cstr(Amount)
+	Else
+		amountBox.Contents = amountBox.Contents & Cstr(Amount)
+	End If
+End Sub
--- a/current/Modules/Archiv/Packtisch/SetupWindow.vbs
+++ b/current/Modules/Archiv/Packtisch/SetupWindow.vbs
@@ -0,0 +1,39 @@
+Sub SetupWindow()
+	Set mywin = CWLStart.CurrentModule.Windows.Item(WINDOW_ID)
+	Set Grid = mywin.Controls.Item(GRID_ID).Grid
+	
+	' Speicher für benutzerdefinierte Felder
+	' (495,0) - Menge Gescannt
+	' (495,1) - Menge Gesamt
+	' (495,2) - Seriennummer
+	' (495,3) - Artikelnummer
+	' (495,4) - Bezeichnung
+	' (495,5) - Chargen-/Identflag
+	CWLCurrentWindow.ActiveWindow.Vars.CreateVar 495, 0, "2", 10
+	CWLCurrentWindow.ActiveWindow.Vars.CreateVar 495, 1, "2", 10
+	CWLCurrentWindow.ActiveWindow.Vars.CreateVar 495, 2, "1", 20
+	CWLCurrentWindow.ActiveWindow.Vars.CreateVar 495, 3, "1", 20
+	CWLCurrentWindow.ActiveWindow.Vars.CreateVar 495, 4, "1", 60
+	CWLCurrentWindow.ActiveWindow.Vars.CreateVar 495, 5, "2", 3
+
+	Grid.InitUserGrid
+	Grid.IsRedraw = False
+	Grid.Header
+	
+	If COLUMNS_CREATED = False Then
+		COLUMN_ARTICLENUMBER = 	Grid.AddColumn("Artikelnummer",	"T21,Artikelnummer",	"1","V",0,495,3,20,scrtflag+sizeflag+hideflag)
+		COLUMN_DESCRIPTION =	Grid.AddColumn("Bezeichnung",	"T21,Bezeichnung",		"1","V",0,495,4,30,scrtflag+sizeflag+hideflag)
+		COLUMN_TOTAL = 			Grid.AddColumn("Gesamt",		"T22,Gesamt",			"1","V",0,495,0,10,scrtflag+sizeflag+hideflag)
+		COLUMN_SCANNED = 		Grid.AddColumn("Gescannt",		"T22,Gescannt",			"1","V",0,495,1,10,scrtflag+sizeflag+hideflag)
+		COLUMN_SERIALNUMBER =	Grid.AddColumn("Seriennummer", 	"T21,Seriennummer",		"l","V",0,495,2,20,scrtflag+sizeflag+hideflag)
+		COLUMN_TYPE =			Grid.AddColumn("SN-Artikel", 	"T17,Artikeltyp",		"l","V",0,495,5,5,scrtflag+sizeflag+hideflag)
+		COLUMNS_CREATED = True
+	End If
+	
+	Grid.IsRedraw = True
+		
+	Set amountBox = mywin.Controls.Item(AMOUNT_INPUT)
+	amountBox.Contents = AMOUNT_PLACEHOLDER
+	
+	MacroCommands.MSetFieldFocus WINDOW_ID, ORDER_INPUT
+End Sub
--- a/current/Modules/Archiv/Packtisch/UpdateArticleRow.vbs
+++ b/current/Modules/Archiv/Packtisch/UpdateArticleRow.vbs
@@ -0,0 +1,45 @@
+' UpdateArticleRow(RowNumber: Integer)
+' ---------------------------------------------------------
+' Trägt die gescannte Menge eines Artikel in das Grid ein
+' - Ändert die Farbe, abhängig von Gesamtmenge und Gescannte Menge
+' 
+' Rückgabewert: Keiner
+' ---------------------------------------------------------
+Sub UpdateArticleRow(RowNumber)
+	Set mywin = CWLStart.CurrentModule.Windows.Item(WINDOW_ID)
+	Set Grid = mywin.Controls.Item(GRID_ID).Grid
+	Set amountBox = mywin.Controls.Item(AMOUNT_INPUT)
+	DebugMessage = ""
+	
+	' Bereits gescannte, Gesamt und Anzahl zu Scannen auslesen
+	Total = Cint(Grid.GetCellValue(RowNumber, COLUMN_TOTAL))
+	Scanned = Cint(Grid.GetCellValue(RowNumber, COLUMN_SCANNED))
+	ScannedAmount = Cint(amountBox.Contents)
+	
+	' Neue bereits gescannte berechnen
+	NewScanned = Scanned + ScannedAmount
+	
+	If DEBUG_ON = True Then
+		AddDebugLine "Total " & Total & vbNewline
+		AddDebugLine "Scanned: " & Scanned & vbNewline
+		AddDebugLine "NewScanned: " & NewScanned & vbNewline
+		
+		ShowDebugBox "UpdateArticleRow"
+	End If
+	
+	' Zeilenfarbe anpassen:
+	' GRÜN: Komplett gescannt
+	' GELB: Teilweise gescannt
+	If NewScanned = Total Then
+		Grid.SetLineColor RowNumber, COLOR_GREEN
+		Grid.SetCellValue RowNumber, COLUMN_SCANNED, NewScanned
+	Elseif NewScanned < Total Then
+		Grid.SetLineColor RowNumber, COLOR_YELLOW
+		Grid.SetCellValue RowNumber, COLUMN_SCANNED, NewScanned
+	Else
+		Message = ""
+		Message = Message & "Eingegebene Menge überschreitet die Gesamt-Anzahl oder" & vbNewline
+		Message = Message & "Artikel wurde bereits vollständig gescannt!"	 
+		Msgbox Message, vbExclamation, DEFAULT_TITLE
+	End If
+End Sub