MONSTER: Rename Monorepo to Modules, only keep Projects under Modules.*

Database/Adapters/Firebird.vb

@@ -0,0 +1,350 @@
+Imports FirebirdSql.Data.FirebirdClient
+Imports System.Text.RegularExpressions
+Imports DigitalData.Modules.Logging
+Imports System.ComponentModel
+
+''' <summary>
+''' MODULE:         Firebird
+''' 
+''' VERSION:        0.0.0.4
+''' 
+''' DATE:           18.12.2018
+''' 
+''' DESCRIPTION:    
+'''                    
+''' DEPENDENCIES:   NLog, >= 4.5.10
+''' 
+'''                 EntityFramework.Firebird, >= 6.4.0
+'''                 
+'''                 FirebirdSql.Data.FirebirdClient, >= 6.4.0
+''' 
+''' PARAMETERS:     LogConfig, DigitalData.Modules.Logging.LogConfig
+'''                 The LogFactory containing the current log config. Used to instanciate the class logger for this and any dependent class
+'''                 
+'''                 DataSource, String
+'''                 The server where the database lives, for example 127.0.0.1 or dd-vmx09-vm03
+'''                 
+'''                 Database, String                
+'''                 The location of the Database in the format `127.0.0.1:E:\Path\To\Database.FDB`
+'''                 
+'''                 User, String
+'''                 The user name to connect as
+'''                 
+'''                 Password, String
+'''                 The user's password
+'''                 
+''' PROPERTIES:     ConnectionEstablished, Boolean
+'''                 If the last opened connection was successful
+''' 
+'''                 ConnectionFailed, Boolean
+'''                 If the last opened connection failed
+'''                 
+'''                 ConnectionString, String
+'''                 The used connectionstring
+'''                 
+''' EXAMPLES:       
+'''                 
+''' REMARKS:        If the connection fails due to "wrong username or password", the cause might be that the server harddrive is full..
+''' </summary>
+Public Class Firebird
+    Private _Logger As Logger
+    Private _LogConfig As LogConfig
+    Private _connectionServer As String
+    Private _connectionDatabase As String
+    Private _connectionUsername As String
+    Private _connectionPassword As String
+    Private _connectionString As String
+    Public _DBInitialized As Boolean = False
+
+    Public Const MAX_POOL_SIZE = 1000
+
+    Public Enum TransactionMode
+        <Description("Use no transaction, neither internal nor external")>
+        NoTransaction
+        <Description("Use the transaction supplied in the Transaction Parameter")>
+        ExternalTransaction
+        <Description("Create an internal transaction on the fly")>
+        WithTransaction
+    End Enum
+
+    Public ReadOnly Property ConnectionString As String
+        Get
+            Return _connectionString
+        End Get
+    End Property
+
+    Public ReadOnly Property DatabaseName As String
+        Get
+            Dim oRegex As New Regex("^\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}:")
+            Dim oPath As String = oRegex.Replace(_connectionDatabase, "")
+            Dim oFileInfo As New IO.FileInfo(oPath)
+            Return oFileInfo.Name
+        End Get
+    End Property
+
+    ''' <summary>
+    ''' 
+    ''' </summary>
+    ''' <param name="LogConfig">The LogFactory containing the current log config. Used to instanciate the class logger for this and any dependent class</param>
+    ''' <param name="Datasource">The server where the database lives, for example 127.0.0.1 or dd-vmx09-vm03</param>
+    ''' <param name="Database">The location of the Database in the format `127.0.0.1:E:\Path\To\Database.FDB`</param>
+    ''' <param name="User">The user name to connect as</param>
+    ''' <param name="Password">The user's password</param>
+    ''' <exception cref="Exceptions.DatabaseException"></exception>
+    Public Sub New(LogConfig As LogConfig, Datasource As String, Database As String, User As String, Password As String)
+        Try
+            _LogConfig = LogConfig
+            _Logger = _LogConfig.GetLogger()
+            Dim oConnectionString = GetConnectionString(Datasource, Database, User, Password)
+
+            _connectionServer = Datasource
+            _connectionDatabase = Database
+            _connectionUsername = User
+            _connectionPassword = Password
+            _connectionString = oConnectionString
+
+            _Logger.Debug("Connecting to database..")
+
+            ' Test the connection
+            Dim oConnection = GetConnection()
+            ' If initial connection was successfully, close it
+            oConnection.Close()
+
+            If oConnection Is Nothing Then
+                Throw New Exceptions.DatabaseException()
+            Else
+                _DBInitialized = True
+            End If
+
+            _Logger.Debug("Connection sucessfully established!")
+        Catch ex As Exception
+            _Logger.Error(ex)
+        End Try
+
+    End Sub
+
+    Public Function GetConnection() As FbConnection
+        Try
+            Dim oConnection = New FbConnection(_connectionString)
+            oConnection.Open()
+
+            Return oConnection
+        Catch ex As Exception
+            _Logger.Error(ex)
+            Return Nothing
+        End Try
+    End Function
+
+    ''' <summary>
+    ''' Builds a connectionstring from the provided arguments.
+    ''' </summary>
+    ''' <param name="DataSource">The database server where to connect to</param>
+    ''' <param name="Database">The datasource, eg. the path of the FDB-file</param>
+    ''' <param name="User">The user used to connect to the database</param>
+    ''' <param name="Password">The password of the connecting user</param>
+    ''' <returns>A connectionstring</returns>
+    Private Function GetConnectionString(DataSource As String, Database As String, User As String, Password As String) As String
+        Return New FbConnectionStringBuilder With {
+            .DataSource = DataSource,
+            .Database = Database,
+            .UserID = User,
+            .Password = Password,
+            .Charset = "UTF8",
+            .MaxPoolSize = MAX_POOL_SIZE
+        }.ToString()
+    End Function
+
+    Private Function MaybeGetTransaction(Connection As FbConnection, Mode As TransactionMode, Transaction As FbTransaction) As FbTransaction
+        If Mode = TransactionMode.NoTransaction Then
+            Return Nothing
+        ElseIf Mode = TransactionMode.ExternalTransaction Then
+            Return Transaction
+        Else
+            Return Connection.BeginTransaction()
+        End If
+    End Function
+
+    Private Function MaybeCommitTransaction(Transaction As FbTransaction, TransactionMode As TransactionMode) As Boolean
+        Select Case TransactionMode
+            Case TransactionMode.NoTransaction
+                Return True
+            Case TransactionMode.ExternalTransaction
+                Return True
+            Case TransactionMode.WithTransaction
+                Try
+                    Transaction.Commit()
+                    Return True
+                Catch ex As Exception
+                    _Logger.Error(ex)
+                    Return False
+                End Try
+            Case Else
+                Return True
+        End Select
+    End Function
+
+    ''' <summary>
+    ''' Executes a non-query command.
+    ''' </summary>
+    ''' <param name="SqlCommand">The command to execute</param>
+    ''' <param name="Connection">The Firebird connection to use</param>
+    ''' <returns>True, if command was executed sucessfully. Otherwise false.</returns>
+    Public Function ExecuteNonQueryWithConnection(SqlCommand As String, Connection As FbConnection, Optional TransactionMode As TransactionMode = TransactionMode.WithTransaction, Optional Transaction As FbTransaction = Nothing) As Boolean
+        _Logger.Debug("Executing Non-Query: {0}", SqlCommand)
+
+        If Connection Is Nothing Then
+            _Logger.Warn("Connection is nothing!")
+            Return Nothing
+        End If
+
+        Dim oTransaction = MaybeGetTransaction(Connection, TransactionMode, Transaction)
+
+        Try
+            Dim oCommand As New FbCommand With {
+                .CommandText = SqlCommand,
+                .Connection = Connection
+            }
+
+            If Not IsNothing(oTransaction) Then
+                oCommand.Transaction = oTransaction
+            End If
+
+            oCommand.ExecuteNonQuery()
+            _Logger.Debug("Command executed!")
+        Catch ex As Exception
+            _Logger.Error(ex, $"Error in ExecuteNonQuery while executing command: [{SqlCommand}]")
+            _Logger.Warn($"Unexpected error in ExecuteNonQueryWithConnection: [{SqlCommand}]")
+            Throw ex
+        Finally
+            MaybeCommitTransaction(oTransaction, TransactionMode)
+        End Try
+
+        Return True
+    End Function
+
+    ''' <summary>
+    ''' Executes a non-query command.
+    ''' </summary>
+    ''' <param name="SqlCommand">The command to execute</param>
+    ''' <returns>True, if command was executed sucessfully. Otherwise false.</returns>
+    Public Function ExecuteNonQuery(SqlCommand As String) As Boolean
+        Using oConnection As FbConnection = GetConnection()
+            Return ExecuteNonQueryWithConnection(SqlCommand, oConnection)
+        End Using
+    End Function
+
+    ''' <summary>
+    ''' Executes a non-query command inside the specified transaction.
+    ''' </summary>
+    ''' <param name="SqlCommand">The command to execute</param>
+    ''' <returns>True, if command was executed sucessfully. Otherwise false.</returns>
+    Public Function ExecuteNonQuery(SqlCommand As String, Transaction As FbTransaction) As Boolean
+        Using oConnection As FbConnection = GetConnection()
+            Return ExecuteNonQueryWithConnection(SqlCommand, oConnection, TransactionMode.ExternalTransaction, Transaction)
+        End Using
+    End Function
+
+    ''' <summary>
+    ''' Executes a sql query resulting in a scalar value.
+    ''' </summary>
+    ''' <param name="SqlQuery">The query to execute</param>
+    ''' <param name="Connection">The Firebird connection to use</param>
+    ''' <returns>The scalar value if the command was executed successfully. Nothing otherwise.</returns>
+    Public Function GetScalarValueWithConnection(SqlQuery As String, Connection As FbConnection, Optional TransactionMode As TransactionMode = TransactionMode.WithTransaction, Optional Transaction As FbTransaction = Nothing) As Object
+        _Logger.Debug("Fetching Scalar-Value: {0}", SqlQuery)
+
+        If Connection Is Nothing Then
+            _Logger.Warn("Connection is nothing!")
+            Return Nothing
+        End If
+
+        Dim oTransaction = MaybeGetTransaction(Connection, TransactionMode, Transaction)
+        Dim oResult As Object
+
+        Try
+            Dim oCommand As New FbCommand With {
+                .CommandText = SqlQuery,
+                .Connection = Connection,
+                .Transaction = oTransaction
+            }
+            oResult = oCommand.ExecuteScalar()
+        Catch ex As Exception
+            _Logger.Error(ex, $"Error in ReturnScalar while executing command: [{SqlQuery}]")
+            Throw ex
+        Finally
+            MaybeCommitTransaction(oTransaction, TransactionMode)
+        End Try
+
+        Return oResult
+    End Function
+
+    ''' <summary>
+    ''' Executes a sql query resulting in a scalar value.
+    ''' </summary>
+    ''' <param name="SqlQuery">The query to execute</param>
+    ''' <returns>The scalar value if the command was executed successfully. Nothing otherwise.</returns>
+    Public Function GetScalarValue(SqlQuery As String) As Object
+        Dim oConnection As FbConnection = GetConnection()
+        Dim oScalarValue As Object = GetScalarValueWithConnection(SqlQuery, oConnection)
+        oConnection.Close()
+
+        Return oScalarValue
+    End Function
+
+    ''' <summary>
+    ''' Executes a sql query resulting in a table of values.
+    ''' </summary>
+    ''' <param name="SqlQuery">The query to execute</param>
+    ''' <param name="Connection">The Firebird connection to use</param>
+    ''' <returns>A datatable containing the results if the command was executed successfully. Nothing otherwise.</returns>
+    Public Function GetDatatableWithConnection(SqlQuery As String, Connection As FbConnection, Optional TransactionMode As TransactionMode = TransactionMode.NoTransaction, Optional Transaction As FbTransaction = Nothing) As DataTable
+        _Logger.Debug("Fetching Datatable: {0}", SqlQuery)
+
+        If Connection Is Nothing Then
+            _Logger.Warn("Connection is nothing!")
+            Return Nothing
+        End If
+
+        Dim oTransaction = MaybeGetTransaction(Connection, TransactionMode, Transaction)
+        Dim oDatatable As New DataTable() With {
+            .TableName = "DDRESULT"
+        }
+
+        Try
+            Dim oAdapter As New FbDataAdapter(New FbCommand With {
+                .CommandText = SqlQuery,
+                .Connection = Connection,
+                .Transaction = oTransaction
+            })
+
+            oAdapter.Fill(oDatatable)
+        Catch ex As Exception
+            _Logger.Error(ex)
+            _Logger.Warn("Error in GetDatatableWithConnection while executing command: [{0}]", SqlQuery)
+            Throw ex
+        Finally
+            MaybeCommitTransaction(oTransaction, TransactionMode)
+        End Try
+
+        Return oDatatable
+    End Function
+
+    ''' <summary>
+    ''' Executes a sql query resulting in a table of values.
+    ''' </summary>
+    ''' <param name="SqlQuery">The query to execute</param>
+    ''' <returns>A datatable containing the results if the command was executed successfully. Nothing otherwise.</returns>
+    Public Function GetDatatable(SqlQuery As String, Optional TransactionMode As TransactionMode = TransactionMode.NoTransaction, Optional Transaction As FbTransaction = Nothing) As DataTable
+        Try
+            Dim oConnection As FbConnection = GetConnection()
+            Dim oDatatable As DataTable = GetDatatableWithConnection(SqlQuery, oConnection, TransactionMode, Transaction)
+            oConnection.Close()
+
+            Return oDatatable
+        Catch ex As Exception
+            _Logger.Error(ex)
+            _Logger.Warn("Error in GetDatatable while executing command: '{0}'", SqlQuery)
+            Throw ex
+        End Try
+    End Function
+End Class

Database/Adapters/MSSQLServer.vb

@@ -0,0 +1,518 @@
+Imports System.ComponentModel
+Imports System.Data.Common
+Imports System.Data.SqlClient
+Imports DigitalData.Modules.Encryption
+Imports DigitalData.Modules.Logging
+Imports DigitalData.Modules.Base
+
+Public Class MSSQLServer
+    Implements IDatabase
+
+    Public Property DBInitialized As Boolean = False Implements IDatabase.DBInitialized
+    Public Property CurrentConnectionString As String = "" Implements IDatabase.CurrentConnectionString
+
+    Private ReadOnly QueryTimeout As Integer
+    Private ReadOnly Logger As Logger
+
+    Public Enum TransactionMode
+        <Description("Use no transaction, neither internal nor external")>
+        NoTransaction
+        <Description("Use the transaction supplied in the Transaction Parameter")>
+        ExternalTransaction
+        <Description("Create an internal transaction on the fly")>
+        WithTransaction
+    End Enum
+
+    Public Sub New(pLogConfig As LogConfig, pConnectionString As String, Optional pTimeout As Integer = Constants.DEFAULT_TIMEOUT)
+        Logger = pLogConfig.GetLogger()
+        QueryTimeout = pTimeout
+
+        Try
+            CurrentConnectionString = pConnectionString
+            DBInitialized = TestCanConnect(CurrentConnectionString)
+        Catch ex As Exception
+            DBInitialized = False
+            Logger.Error(ex)
+        End Try
+    End Sub
+
+    Public Sub New(pLogConfig As LogConfig, Server As String, Database As String, UserId As String, Password As String, Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT)
+        Logger = pLogConfig.GetLogger()
+        QueryTimeout = Timeout
+
+        Try
+            CurrentConnectionString = GetConnectionString(Server, Database, UserId, Password)
+            DBInitialized = TestCanConnect(CurrentConnectionString)
+        Catch ex As Exception
+            DBInitialized = False
+            Logger.Error(ex)
+        End Try
+    End Sub
+
+    ''' <summary>
+    ''' Encrypts a connection string password.
+    ''' </summary>
+    ''' <param name="pConnectionString">A connection string with a plain-text password</param>
+    ''' <returns>The connection string with the password encrypted.</returns>
+    <DebuggerStepThrough()>
+    Public Shared Function EncryptConnectionString(pConnectionString As String) As String
+        Dim oEncryption As New EncryptionLegacy()
+        Dim oBuilder As New SqlConnectionStringBuilder() With {.ConnectionString = pConnectionString}
+        Dim oEncryptedPassword = oEncryption.EncryptData(oBuilder.Password)
+        oBuilder.Password = oEncryptedPassword
+
+        Return oBuilder.ToString()
+    End Function
+
+    ''' <summary>
+    ''' Decrypts a connection string password.
+    ''' </summary>
+    ''' <param name="pConnectionString">A connection string with a encrypted password</param>
+    ''' <returns>The connection string with the password decrypted.</returns>
+    <DebuggerStepThrough()>
+    Public Shared Function DecryptConnectionString(pConnectionString As String) As String
+        Dim oEncryption As New EncryptionLegacy()
+        Dim oBuilder As New SqlConnectionStringBuilder() With {.ConnectionString = pConnectionString}
+        Dim oDecryptedPassword = oEncryption.DecryptData(oBuilder.Password)
+        oBuilder.Password = oDecryptedPassword
+
+        Return oBuilder.ToString()
+    End Function
+
+    <DebuggerStepThrough()>
+    Public Function GetConnectionString(Server As String, Database As String, UserId As String, Password As String) As String
+        Dim oConnectionStringBuilder As New SqlConnectionStringBuilder() With {
+            .DataSource = Server,
+            .InitialCatalog = Database,
+            .UserID = UserId,
+            .Password = Password
+        }
+
+        Return oConnectionStringBuilder.ToString
+    End Function
+
+    <DebuggerStepThrough()>
+    Public Function GetConnection() As SqlConnection
+        Try
+            Dim oConnection = GetSQLConnection()
+            Return oConnection
+        Catch ex As Exception
+            Logger.Error(ex)
+            Return Nothing
+        End Try
+    End Function
+
+    <DebuggerStepThrough()>
+    Private Function MaybeGetTransaction(Connection As SqlConnection, Mode As TransactionMode, Transaction As SqlTransaction) As SqlTransaction
+        If Connection Is Nothing Then
+            Throw New ArgumentNullException("Connection")
+        End If
+
+        If Mode = TransactionMode.NoTransaction Then
+            Return Nothing
+        ElseIf Mode = TransactionMode.ExternalTransaction Then
+            Return Transaction
+        Else
+            Return Connection.BeginTransaction()
+        End If
+    End Function
+
+    <DebuggerStepThrough()>
+    Private Function MaybeCommitTransaction(Transaction As SqlTransaction, TransactionMode As TransactionMode) As Boolean
+        Select Case TransactionMode
+            Case TransactionMode.NoTransaction
+                Return True
+            Case TransactionMode.ExternalTransaction
+                Return True
+            Case TransactionMode.WithTransaction
+                Try
+                    Transaction.Commit()
+                    Return True
+                Catch ex As Exception
+                    Logger.Error(ex)
+                    Return False
+                End Try
+            Case Else
+                Return True
+        End Select
+    End Function
+
+    Public Function GetConnectionStringForId(pConnectionId As Integer) As String
+        Return Get_ConnectionStringforID(pConnectionId)
+    End Function
+
+    Public Function Get_ConnectionStringforID(pConnectionId As Integer) As String
+        Dim oConnectionString As String = String.Empty
+
+        Logger.Debug("Getting ConnectionString for ConnectionId [{0}]", pConnectionId)
+
+        If pConnectionId = 0 Then
+            Logger.Warn("ConnectionId was 0. Falling back to default connection.")
+            Return String.Empty
+        End If
+
+        Try
+            Dim oTable As DataTable = GetDatatable($"SELECT * FROM TBDD_CONNECTION WHERE GUID = {pConnectionId}")
+            If oTable.Rows.Count = 1 Then
+                Dim oRow As DataRow = oTable.Rows(0)
+                Dim oProvider = oRow.Item("SQL_PROVIDER").ToString.ToUpper
+                Dim oServer = oRow.Item("SERVER")
+                Dim oDatabase = oRow.Item("DATENBANK")
+                Dim oUser = oRow.Item("USERNAME")
+                Dim oPassword = oRow.Item("PASSWORD")
+
+                Select Case oProvider
+                    Case "MS-SQL"
+                        If oUser = "WINAUTH" Then
+                            oConnectionString = $"Server={oServer};Database={oDatabase};Trusted_Connection=True;"
+                        Else
+                            oConnectionString = $"Server={oServer};Database={oDatabase};User Id={oUser};Password={oPassword};"
+                        End If
+
+                    Case "ORACLE"
+                        If oRow.Item("BEMERKUNG").ToString.Contains("without tnsnames") Then
+                            oConnectionString = $"Data Source=(DESCRIPTION=(ADDRESS_LIST=(ADDRESS=(PROTOCOL=TCP)(HOST={oServer})(PORT=1521)))(CONNECT_DATA=(SERVER=DEDICATED)(SERVICE_NAME={oDatabase})));User Id={oUser};Password={oPassword};"
+                        Else
+                            oConnectionString = $"Data Source={oServer};Persist Security Info=True;User Id={oUser};Password={oPassword};Unicode=True"
+                        End If
+
+                    Case Else
+                        Logger.Warn("Provider [{0}] not supported!", oProvider)
+
+                End Select
+
+            Else
+                Logger.Warn("No entry for Connection-ID: [{0}] ", pConnectionId.ToString)
+            End If
+
+        Catch ex As Exception
+            Logger.Error(ex)
+            Logger.Warn("Error in Get_ConnectionStringforID")
+        End Try
+
+        Return DecryptConnectionString(oConnectionString)
+    End Function
+
+    <DebuggerStepThrough()>
+    Private Function TestCanConnect() As Boolean
+        Return TestCanConnect(CurrentConnectionString)
+    End Function
+
+    Private Function TestCanConnect(pConnectionString As String) As Boolean
+        Try
+            Logger.Debug("Testing connection to [{0}]", MaskConnectionString(pConnectionString))
+
+            Dim oDecryptedConnectionString = DecryptConnectionString(pConnectionString)
+            Dim oConnection As New SqlConnection(oDecryptedConnectionString)
+            OpenSQLConnection(oConnection)
+            oConnection.Close()
+            Return True
+        Catch ex As Exception
+            Logger.Error(ex)
+            Return False
+        End Try
+    End Function
+
+    ''' <summary>
+    ''' This Function intentionally has no try..catch block to have any errors caught outside
+    ''' </summary>
+    ''' <param name="Connection"></param>
+    ''' <returns></returns>
+    Private Function OpenSQLConnection(Connection As SqlConnection) As SqlConnection
+        If Connection.State = ConnectionState.Closed Then
+            Connection.Open()
+        End If
+
+        Return Connection
+    End Function
+
+    <DebuggerStepThrough()>
+    Private Function GetSQLConnection() As SqlConnection
+        Return GetConnection(CurrentConnectionString)
+    End Function
+
+    Private Function GetConnection(pConnectionString As String) As SqlConnection
+        Try
+            Dim oConnection As New SqlConnection(pConnectionString)
+            oConnection = OpenSQLConnection(oConnection)
+
+            Dim oMaskedConnectionString = MaskConnectionString(pConnectionString)
+            Logger.Debug("The Following Connection is open: {0}", oMaskedConnectionString)
+
+            Return oConnection
+        Catch ex As Exception
+            Logger.Error(ex)
+
+            Return Nothing
+        End Try
+    End Function
+
+    <DebuggerStepThrough()>
+    Private Function MaskConnectionString(pConnectionString As String) As String
+        Try
+            If pConnectionString Is Nothing OrElse pConnectionString.Length = 0 Then
+                Logger.Warn("Connection String is empty!")
+                Throw New ArgumentNullException("pConnectionString")
+            End If
+
+            Dim oBuilder As New SqlConnectionStringBuilder() With {.ConnectionString = pConnectionString}
+            Dim oConnectionString = pConnectionString.Replace(oBuilder.Password, "XXXXX")
+            Return oConnectionString
+        Catch ex As Exception
+            Logger.Error(ex)
+            Return "Invalid ConnectionString"
+        End Try
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function GetDatatable(SqlCommand As String) As DataTable Implements IDatabase.GetDatatable
+        Return GetDatatable(SqlCommand, QueryTimeout)
+    End Function
+
+    ''' <summary>
+    ''' Returns a datatable for a sql-statement 
+    ''' </summary>
+    ''' <param name="SqlCommand">sqlcommand for datatable (select XYZ from TableORView)</param>
+    ''' <returns>Returns a datatable</returns>
+    Public Function GetDatatable(SqlCommand As String, Timeout As Integer) As DataTable Implements IDatabase.GetDatatable
+        Using oSqlConnection = GetSQLConnection()
+            Return GetDatatableWithConnectionObject(SqlCommand, oSqlConnection, TransactionMode.WithTransaction, Nothing, Timeout)
+        End Using
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function GetDatatable(SqlCommand As String, Transaction As SqlTransaction, Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As DataTable
+        Using oSqlConnection = GetSQLConnection()
+            Return GetDatatableWithConnectionObject(SqlCommand, oSqlConnection, TransactionMode.ExternalTransaction, Transaction, Timeout)
+        End Using
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Async Function GetDatatableAsync(SqlCommand As String, Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As Task(Of DataTable)
+        Return Await Task.Run(Function() GetDatatable(SqlCommand, Timeout))
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function GetDatatableWithConnection(SqlCommand As String, pConnectionString As String, Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As DataTable
+        Using oConnection = GetConnection(pConnectionString)
+            Return GetDatatableWithConnectionObject(SqlCommand, oConnection, Timeout:=Timeout)
+        End Using
+    End Function
+
+    Public Function GetDatatableWithConnectionObject(SqlCommand As String, SqlConnection As SqlConnection,
+                                                     Optional TransactionMode As TransactionMode = TransactionMode.WithTransaction,
+                                                     Optional Transaction As SqlTransaction = Nothing,
+                                                     Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As DataTable
+        Dim oTransaction As SqlTransaction = MaybeGetTransaction(SqlConnection, TransactionMode, Transaction)
+        Dim oTable As New DataTable() With {.TableName = Constants.DEFAULT_TABLE}
+
+        Try
+            Dim oAdapter As New SqlDataAdapter(New SqlCommand With {
+                .CommandText = SqlCommand,
+                .Connection = SqlConnection,
+                .Transaction = oTransaction,
+                .CommandTimeout = Timeout
+            })
+
+            Logger.Debug("GetDatatableWithConnectionObject: Running Query [{0}]", SqlCommand)
+
+            oAdapter.Fill(oTable)
+        Catch ex As Exception
+            Logger.Error(ex)
+            Logger.Warn("GetDatatableWithConnectionObject: Error in GetDatatableWithConnection while executing command: [{0}]", SqlCommand)
+            Throw ex
+        Finally
+            MaybeCommitTransaction(oTransaction, TransactionMode)
+        End Try
+
+        Return oTable
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function ExecuteNonQuery(SQLCommand As String) As Boolean Implements IDatabase.ExecuteNonQuery
+        Using oConnection = GetSQLConnection()
+            Return ExecuteNonQueryWithConnectionObject(SQLCommand, oConnection, TransactionMode.WithTransaction, Nothing, QueryTimeout)
+        End Using
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function ExecuteNonQuery(SQLCommand As String, Timeout As Integer) As Boolean Implements IDatabase.ExecuteNonQuery
+        Using oConnection = GetSQLConnection()
+            Return ExecuteNonQueryWithConnectionObject(SQLCommand, oConnection, TransactionMode.WithTransaction, Nothing, Timeout)
+        End Using
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function ExecuteNonQuery(SQLCommand As String, Transaction As SqlTransaction, Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As Boolean
+        Using oConnection = GetSQLConnection()
+            Return ExecuteNonQueryWithConnectionObject(SQLCommand, Transaction.Connection, TransactionMode.ExternalTransaction, Transaction, Timeout)
+        End Using
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Async Function ExecuteNonQueryAsync(SQLCommand As String, Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As Task(Of Boolean)
+        Return Await Task.Run(Function() ExecuteNonQuery(SQLCommand, Timeout))
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function ExecuteNonQueryWithConnection(pSQLCommand As String, ConnString As String, Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As Boolean
+        Using oConnection = GetConnection(ConnString)
+            Return ExecuteNonQueryWithConnectionObject(pSQLCommand, oConnection, TransactionMode.WithTransaction, Nothing, Timeout)
+        End Using
+    End Function
+
+    Public Function ExecuteNonQueryWithConnectionObject(SqlCommand As String, SqlConnection As SqlConnection,
+                                                        Optional TransactionMode As TransactionMode = TransactionMode.WithTransaction,
+                                                        Optional Transaction As SqlTransaction = Nothing,
+                                                        Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As Boolean
+        Dim oTransaction As SqlTransaction = MaybeGetTransaction(SqlConnection, TransactionMode, Transaction)
+
+        Try
+            Logger.Debug("ExecuteNonQueryWithConnectionObject: Running Command [{0}]", SqlCommand)
+
+            Using oSQLCOmmand = SqlConnection.CreateCommand()
+                oSQLCOmmand.CommandText = SqlCommand
+                oSQLCOmmand.CommandTimeout = Timeout
+                oSQLCOmmand.Transaction = oTransaction
+                oSQLCOmmand.ExecuteNonQuery()
+            End Using
+
+            Return True
+        Catch ex As Exception
+            Logger.Error(ex)
+            Logger.Warn("ExecuteNonQueryWithConnectionObject: Error in ExecuteNonQueryWithConnectionObject while executing command: [{0}]-[{1}]", SqlCommand, SqlConnection.ConnectionString)
+            Return False
+        Finally
+            MaybeCommitTransaction(oTransaction, TransactionMode)
+        End Try
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function GetScalarValue(SQLQuery As String) As Object Implements IDatabase.GetScalarValue
+        Using oConnection As SqlConnection = GetSQLConnection()
+            Return GetScalarValueWithConnectionObject(SQLQuery, oConnection)
+        End Using
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function GetScalarValue(SQLCommand As String, Timeout As Integer) As Object Implements IDatabase.GetScalarValue
+        Using oConnection = GetSQLConnection()
+            Return GetScalarValueWithConnectionObject(SQLCommand, oConnection, TransactionMode.WithTransaction, Nothing, Timeout)
+        End Using
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function GetScalarValue(SQLCommand As String, Transaction As SqlTransaction, Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As Object
+        Using oConnection = GetSQLConnection()
+            Return GetScalarValueWithConnectionObject(SQLCommand, oConnection, TransactionMode.ExternalTransaction, Transaction, Timeout)
+        End Using
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Async Function GetScalarValueAsync(SQLQuery As String, Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As Task(Of Object)
+        Return Await Task.Run(Function() GetScalarValue(SQLQuery, Timeout))
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function GetScalarValueWithConnection(SQLCommand As String, pConnectionString As String, Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As Object
+        Using oConnection = GetConnection(pConnectionString)
+            Return GetScalarValueWithConnectionObject(SQLCommand, oConnection, TransactionMode.WithTransaction, Nothing, Timeout)
+        End Using
+    End Function
+
+    Public Function GetScalarValueWithConnectionObject(SqlCommand As String, SqlConnection As SqlConnection,
+                                                       Optional TransactionMode As TransactionMode = TransactionMode.WithTransaction,
+                                                       Optional Transaction As SqlTransaction = Nothing,
+                                                       Optional Timeout As Integer = Constants.DEFAULT_TIMEOUT) As Object
+
+        Dim oTransaction As SqlTransaction = MaybeGetTransaction(SqlConnection, TransactionMode, Transaction)
+        Dim oResult As Object = Nothing
+
+        Try
+            Using oSQLCOmmand = SqlConnection.CreateCommand()
+                oSQLCOmmand.CommandText = SqlCommand
+                oSQLCOmmand.CommandTimeout = Timeout
+                oSQLCOmmand.Transaction = oTransaction
+
+                oResult = oSQLCOmmand.ExecuteScalar()
+            End Using
+        Catch ex As Exception
+            Logger.Error(ex)
+            Logger.Warn("GetDatatableWithConnectionObject: Error in GetDatatableWithConnection while executing command: [{0}]", SqlCommand)
+        Finally
+            MaybeCommitTransaction(oTransaction, TransactionMode)
+        End Try
+
+        Return oResult
+    End Function
+
+    Public Function GetScalarValue(SQLCommand As SqlCommand, OutputParameter As String, Timeout As Integer) As Object
+        Try
+            If TestCanConnect() = False Then
+                Return Nothing
+            End If
+
+            Logger.Debug("GetScalarValue: Running Query [{0}]", SQLCommand)
+
+            If SQLCommand.CommandText.Contains(" ") Then
+                SQLCommand.CommandType = CommandType.Text
+            Else
+                SQLCommand.CommandType = CommandType.StoredProcedure
+            End If
+
+            Using oConnection As SqlConnection = GetSQLConnection()
+
+                SQLCommand.Connection = oConnection
+                SQLCommand.Parameters(OutputParameter).Direction = ParameterDirection.Output
+                SQLCommand.CommandTimeout = Timeout
+                SQLCommand.ExecuteNonQuery()
+                oConnection.Close()
+
+                Return SQLCommand.Parameters(OutputParameter).Value
+            End Using
+        Catch ex As Exception
+            Logger.Error(ex)
+            Logger.Warn($"GetScalarValue failed SQLCommand [{SQLCommand}]")
+
+            Return Nothing
+        End Try
+    End Function
+
+    '<DebuggerStepThrough()>
+    Public Function GetScalarValue(SQLCommand As SqlCommand, OutputParameter As String) As Object
+        Return GetScalarValue(SQLCommand, OutputParameter, QueryTimeout)
+    End Function
+
+    ''' <summary>
+    ''' Executes the passed sql-statement in asyncmode
+    ''' </summary>
+    ''' <param name="SqlCommand">the sql statement</param>
+    ''' <param name="commandtimeout">Optional Timeout</param>
+    ''' <remarks></remarks>
+    Public Sub NewExecuteNonQueryAsync(SqlCommand As String, Optional commandtimeout As Integer = Constants.DEFAULT_TIMEOUT)
+        Logger.Debug("NewExecuteNonQueryAsync: Running Query [{0}]", SqlCommand)
+
+        Try
+            Dim oCallback As New AsyncCallback(AddressOf NewExecuteNonQueryAsync_Callback)
+
+            Using oConnection As SqlConnection = GetSQLConnection()
+                Using oSQLCOmmand = oConnection.CreateCommand()
+                    oSQLCOmmand.CommandText = SqlCommand
+                    oSQLCOmmand.CommandTimeout = commandtimeout
+                    oSQLCOmmand.BeginExecuteNonQuery(oCallback, oSQLCOmmand)
+                End Using
+            End Using
+        Catch ex As Exception
+            Logger.Error(ex)
+            Logger.Warn($"NewExecuteNonQueryAsync failed SQLCommand [{SqlCommand}]")
+
+        End Try
+    End Sub
+
+    '<DebuggerStepThrough()>
+    Private Sub NewExecuteNonQueryAsync_Callback(ByVal result As IAsyncResult)
+        Dim command As SqlCommand = CType(result.AsyncState, SqlCommand)
+        Dim res = command.EndExecuteNonQuery(result)
+        Logger.Info("Finished executing Async database operation: {0}", command.CommandText)
+    End Sub
+End Class

Database/Adapters/ODBC.vb

@@ -0,0 +1,179 @@
+Imports System.Data.Odbc
+Imports DigitalData.Modules.Logging
+
+Public Class ODBC
+    Private _Logger As Logger
+    Private _LogConfig As LogConfig
+
+    Private _connectionDatasource As String
+    Private _connectionUsername As String
+    Private _connectionPassword As String
+    Private _connectionString As String
+
+    Public Sub New(LogConfig As LogConfig, Datasource As String, User As String, Password As String)
+        Try
+            _LogConfig = LogConfig
+            _Logger = _LogConfig.GetLogger()
+
+            _connectionDatasource = Datasource
+            _connectionPassword = Password
+            _connectionUsername = User
+            _connectionString = GetConnectionString(Datasource, User, Password)
+
+            _Logger.Debug("Connecting to database..")
+
+            ' Test the connection
+            Dim oConnection = GetConnection()
+
+            If oConnection Is Nothing Then
+                Throw New Exceptions.DatabaseException()
+            End If
+
+            ' If initial connection was successfully, close it
+            oConnection.Close()
+
+            _Logger.Debug("Connection sucessfully established!")
+        Catch ex As Exception
+            _Logger.Error(ex)
+        End Try
+    End Sub
+
+    Public Function GetConnection() As OdbcConnection
+        Try
+            Dim oConnection As New OdbcConnection(_connectionString)
+            oConnection.Open()
+
+            Return oConnection
+        Catch ex As Exception
+            _Logger.Error(ex)
+            Return Nothing
+        End Try
+    End Function
+
+    Public Function GetConnectionString(Datasource As String, User As String, Password As String) As Object
+        Return $"DSN={Datasource};UID={User};PWD={Password}"
+    End Function
+
+    ''' <summary>
+    ''' Executes a non-query command.
+    ''' </summary>
+    ''' <param name="SqlQuery">The command to execute</param>
+    ''' <param name="Connection">The Firebird connection to use</param>
+    ''' <returns>True, if command was executed sucessfully. Otherwise false.</returns>
+    Public Function ExecuteNonQueryWithConnection(SqlQuery As String, Connection As OdbcConnection) As Object
+        _Logger.Debug("Fetching Non-Query: {0}", SqlQuery)
+
+        Dim oResult As Object
+
+        If Connection Is Nothing Then
+            _Logger.Warn("Connection is nothing!")
+            Return Nothing
+        End If
+
+        Try
+            Dim oCommand As New OdbcCommand(SqlQuery, Connection)
+            oResult = oCommand.ExecuteNonQuery()
+        Catch ex As Exception
+            _Logger.Error(ex, $"Error in ExecuteNonQueryWithConnection while executing command: '{SqlQuery}'")
+            Throw ex
+        End Try
+
+        Return oResult
+    End Function
+
+    ''' <summary>
+    ''' Executes a non-query command.
+    ''' </summary>
+    ''' <param name="SqlCommand">The command to execute</param>
+    ''' <returns>True, if command was executed sucessfully. Otherwise false.</returns>
+    Public Function ExecuteNonQuery(SqlCommand As String) As Boolean
+        Dim oConnection As OdbcConnection = GetConnection()
+        Dim oScalarValue As Object = ExecuteNonQueryWithConnection(SqlCommand, oConnection)
+        oConnection.Close()
+
+        Return oScalarValue
+    End Function
+
+    ''' <summary>
+    ''' Executes a sql query resulting in a scalar value.
+    ''' </summary>
+    ''' <param name="SqlQuery">The query to execute</param>
+    ''' <param name="Connection">The Firebird connection to use</param>
+    ''' <returns>The scalar value if the command was executed successfully. Nothing otherwise.</returns>
+    Public Function GetScalarValueWithConnection(SqlQuery As String, Connection As OdbcConnection) As Object
+        _Logger.Debug("Fetching Datatable: {0}", SqlQuery)
+
+        Dim oResult As Object
+
+        If Connection Is Nothing Then
+            _Logger.Warn("Connection is nothing!")
+            Return Nothing
+        End If
+
+        Try
+            Dim oCommand As New OdbcCommand(SqlQuery, Connection)
+            oResult = oCommand.ExecuteScalar()
+        Catch ex As Exception
+            _Logger.Error(ex, $"Error in GetDatatableWithConnection while executing command: '{SqlQuery}'")
+            Throw ex
+        End Try
+
+        Return oResult
+    End Function
+
+    ''' <summary>
+    ''' Executes a sql query resulting in a table of values.
+    ''' </summary>
+    ''' <param name="SqlQuery">The query to execute</param>
+    ''' <returns>A datatable containing the results if the command was executed successfully. Nothing otherwise.</returns>
+    Public Function GetScalarValue(SqlQuery As String) As Object
+        Dim oConnection As OdbcConnection = GetConnection()
+        Dim oDatatable As DataTable = GetDatatableWithConnection(SqlQuery, oConnection)
+        oConnection.Close()
+
+        Return oDatatable
+    End Function
+
+    ''' <summary>
+    ''' Executes a sql query resulting in a table of values.
+    ''' </summary>
+    ''' <param name="SqlQuery">The query to execute</param>
+    ''' <param name="Connection">The Firebird connection to use</param>
+    ''' <returns>A datatable containing the results if the command was executed successfully. Nothing otherwise.</returns>
+    Public Function GetDatatableWithConnection(SqlQuery As String, Connection As OdbcConnection) As DataTable
+        _Logger.Debug("Fetching Datatable: {0}", SqlQuery)
+
+        Dim oDatatable As New DataTable() With {
+            .TableName = "DDRESULT"
+        }
+
+        If Connection Is Nothing Then
+            _Logger.Warn("Connection is nothing!")
+            Return Nothing
+        End If
+
+        Try
+
+            Dim oAdapter As New OdbcDataAdapter(SqlQuery, Connection)
+            oAdapter.Fill(oDatatable)
+        Catch ex As Exception
+            _Logger.Error(ex, $"Error in GetDatatableWithConnection while executing command: '{SqlQuery}'")
+            Throw ex
+        End Try
+
+        Return oDatatable
+    End Function
+
+    ''' <summary>
+    ''' Executes a sql query resulting in a table of values.
+    ''' </summary>
+    ''' <param name="SqlQuery">The query to execute</param>
+    ''' <returns>A datatable containing the results if the command was executed successfully. Nothing otherwise.</returns>
+    Public Function GetDatatable(SqlQuery As String) As DataTable
+        Dim oConnection As OdbcConnection = GetConnection()
+        Dim oDatatable As DataTable = GetDatatableWithConnection(SqlQuery, oConnection)
+        oConnection.Close()
+
+        Return oDatatable
+    End Function
+End Class

Database/Adapters/Oracle.vb

@@ -0,0 +1,253 @@
+Imports DigitalData.Modules.Encryption
+Imports DigitalData.Modules.Logging
+Imports Oracle.ManagedDataAccess.Client
+
+Public Class Oracle
+    Implements IDatabase
+
+    Public Property DBInitialized As Boolean = False Implements IDatabase.DBInitialized
+    Public Property CurrentConnectionString As String = "" Implements IDatabase.CurrentConnectionString
+
+    Private ReadOnly _Timeout As Integer
+    Private ReadOnly _Logger As Logger
+
+    Public Sub New(LogConfig As LogConfig, ConnectionString As String, Optional Timeout As Integer = 120)
+        _Timeout = Timeout
+        _Logger = LogConfig.GetLogger()
+
+        ConnectionString = ConnectionString
+        DBInitialized = TestCanConnect(ConnectionString)
+    End Sub
+
+    Public Sub New(LogConfig As LogConfig, Server As String, Database As String, UserId As String, Password As String, Optional Timeout As Integer = 120)
+        _Timeout = Timeout
+        _Logger = LogConfig.GetLogger()
+
+        CurrentConnectionString = GetConnectionString(Server, Database, UserId, Password)
+        DBInitialized = TestCanConnect(CurrentConnectionString)
+    End Sub
+
+    Private Function TestCanConnect(ConnectionString As String) As Boolean
+        Try
+            Dim oSQLconnect As New OracleConnection
+            oSQLconnect.ConnectionString = ConnectionString
+            oSQLconnect.Open()
+            oSQLconnect.Close()
+            Return True
+        Catch ex As Exception
+            _Logger.Error(ex)
+            Return False
+        End Try
+    End Function
+
+    Public Shared Function GetConnectionString(Server As String, Database As String, UserId As String, Password As String) As String
+        Dim oConnectionString = $"Data Source=(DESCRIPTION=(ADDRESS_LIST=(ADDRESS=(PROTOCOL=TCP)(HOST={Server})(PORT=1521)))(CONNECT_DATA=(SERVER=DEDICATED)(SERVICE_NAME={Database})));User Id={UserId};Password={Password};"
+        Return oConnectionString
+    End Function
+
+    ''' <summary>
+    ''' Encrypts a connection string password.
+    ''' </summary>
+    ''' <param name="ConnectionString">A connection string with a plain-text password</param>
+    ''' <returns>The connection string with the password encrypted.</returns>
+    <DebuggerStepThrough()>
+    Public Shared Function EncryptConnectionString(ConnectionString As String) As String
+        Dim oEncryption As New EncryptionLegacy()
+        Dim oBuilder As New OracleConnectionStringBuilder() With {.ConnectionString = ConnectionString}
+        Dim oEncryptedPassword = oEncryption.EncryptData(oBuilder.Password)
+        oBuilder.Password = oEncryptedPassword
+
+        Return oBuilder.ToString()
+    End Function
+
+    ''' <summary>
+    ''' Decrypts a connection string password.
+    ''' </summary>
+    ''' <param name="ConnectionString">A connection string with a encrypted password</param>
+    ''' <returns>The connection string with the password decrypted.</returns>
+    <DebuggerStepThrough()>
+    Public Shared Function DecryptConnectionString(ConnectionString As String) As String
+        Dim oEncryption As New EncryptionLegacy()
+        Dim oBuilder As New OracleConnectionStringBuilder() With {.ConnectionString = ConnectionString}
+        Dim oDecryptedPassword = oEncryption.DecryptData(oBuilder.Password)
+        oBuilder.Password = oDecryptedPassword
+
+        Return oBuilder.ToString()
+    End Function
+
+
+    ''' <summary>
+    ''' Executes the passed sql-statement 
+    ''' </summary>
+    ''' <param name="executeStatement">the sql statement</param>
+    ''' <returns>Returns true if properly executed, else false</returns>
+    Public Function NewExecutenonQuery(executeStatement As String) As Boolean
+        Try
+            Dim oSQLconnect As New OracleConnection
+            Dim oSQLCOmmand As OracleCommand
+            oSQLconnect.ConnectionString = CurrentConnectionString
+            oSQLconnect.Open()
+            oSQLCOmmand = oSQLconnect.CreateCommand()
+            oSQLCOmmand.CommandText = executeStatement
+            oSQLCOmmand.CommandTimeout = _Timeout
+            oSQLCOmmand.ExecuteNonQuery()
+            oSQLCOmmand.Dispose()
+            oSQLconnect.Close()
+            Return True
+        Catch ex As Exception
+            _Logger.Error(ex)
+            _Logger.Debug("executeStatement: " & executeStatement)
+            Return False
+        End Try
+    End Function
+
+    ''' <summary>
+    ''' Executes the passed sql-statement as Scalar
+    ''' </summary>
+    ''' <param name="executeStatement">the sql statement</param>
+    ''' <returns>Returns the scalarvalue</returns> 
+    Public Function NewExecuteScalar(executeStatement As String)
+        Dim result
+        Try
+            Dim oSQLconnect As New OracleConnection
+            Dim oSQLCOmmand As OracleCommand
+            oSQLconnect.ConnectionString = CurrentConnectionString
+            oSQLconnect.Open()
+            oSQLCOmmand = oSQLconnect.CreateCommand()
+            oSQLCOmmand.CommandText = executeStatement
+            oSQLCOmmand.CommandTimeout = _Timeout
+            result = oSQLCOmmand.ExecuteScalar()
+            oSQLCOmmand.Dispose()
+            oSQLconnect.Close()
+            Return result
+        Catch ex As Exception
+            _Logger.Error(ex)
+            _Logger.Debug("executeStatement: " & executeStatement)
+            Throw ex
+        End Try
+    End Function
+
+    Public Function GetDatatable(pSQLCommand As String, pTimeout As Integer) As DataTable Implements IDatabase.GetDatatable
+        Try
+            Using oConnection = GetConnection(CurrentConnectionString)
+                Dim oSQLCommand As OracleCommand
+                oSQLCommand = oConnection.CreateCommand()
+                oSQLCommand.CommandText = pSQLCommand
+                oSQLCommand.CommandTimeout = pTimeout
+
+                Dim oAdapter As OracleDataAdapter = New OracleDataAdapter(oSQLCommand)
+                Dim oTable As DataTable = New DataTable()
+
+                _Logger.Debug("GetDatatable: Running Query [{0}]", oSQLCommand)
+
+                oAdapter.Fill(oTable)
+
+                Return oTable
+            End Using
+        Catch ex As Exception
+            _Logger.Error(ex)
+            _Logger.Warn("GetDatatable: Error in GetDatatable while executing command: [{0}]", pSQLCommand)
+            Return Nothing
+        End Try
+    End Function
+
+    Private Function GetDatatable(pSQLCommand As String) As DataTable Implements IDatabase.GetDatatable
+        Return GetDatatable(pSQLCommand, _Timeout)
+    End Function
+
+    Public Function ExecuteNonQuery(pSQLCommand As String, pTimeout As Integer) As Boolean Implements IDatabase.ExecuteNonQuery
+        Try
+            Using oConnection = GetConnection(CurrentConnectionString)
+                Dim oSQLCOmmand As OracleCommand
+                oSQLCOmmand = oConnection.CreateCommand()
+                oSQLCOmmand.CommandText = pSQLCommand
+                oSQLCOmmand.CommandTimeout = pTimeout
+
+
+                _Logger.Debug("ExecuteNonQuery: Running Query [{0}]", oSQLCOmmand)
+                oSQLCOmmand.ExecuteNonQuery()
+                oSQLCOmmand.Dispose()
+                Return True
+            End Using
+        Catch ex As Exception
+            _Logger.Error(ex)
+            _Logger.Warn("ExecuteNonQuery: Error in ExecuteNonQuery while executing command: [{0}]", pSQLCommand)
+            Return False
+        End Try
+    End Function
+
+    Public Function ExecuteNonQuery(pSQLCommand As String) As Boolean Implements IDatabase.ExecuteNonQuery
+        Return ExecuteNonQuery(pSQLCommand, _Timeout)
+    End Function
+
+    Public Function GetScalarValue(pSQLCommand As String, pTimeout As Integer) As Object Implements IDatabase.GetScalarValue
+        Dim result
+        Try
+            Using oConnection = GetConnection(CurrentConnectionString)
+                Dim oSQLCOmmand As OracleCommand
+                oSQLCOmmand = oConnection.CreateCommand()
+                oSQLCOmmand.CommandText = pSQLCommand
+                oSQLCOmmand.CommandTimeout = pTimeout
+
+                _Logger.Debug("GetScalarValue: Running Query [{0}]", oSQLCOmmand)
+                result = oSQLCOmmand.ExecuteScalar()
+
+                Return result
+            End Using
+
+        Catch ex As Exception
+            _Logger.Error(ex)
+            _Logger.Warn("GetScalarValue: Error in GetScalarValue while executing command: [{0}]", pSQLCommand)
+            Throw ex
+        End Try
+    End Function
+
+    Public Function GetScalarValue(pSQLCommand As String) As Object Implements IDatabase.GetScalarValue
+        Return GetScalarValue(pSQLCommand, _Timeout)
+    End Function
+
+    Private Function GetConnection(ConnectionString As String) As OracleConnection
+        Try
+            Dim oConnection As New OracleConnection(ConnectionString)
+            oConnection = OpenSQLConnection(oConnection)
+
+            Dim oMaskedConnectionString = MaskConnectionString(ConnectionString)
+            _Logger.Debug("The Following Connection is open: {0}", oMaskedConnectionString)
+
+            Return oConnection
+        Catch ex As Exception
+            _Logger.Error(ex)
+
+            Return Nothing
+        End Try
+    End Function
+
+    ''' <summary>
+    ''' This Function intentionally has no try..catch block to have any errors caught outside
+    ''' </summary>
+    ''' <param name="Connection"></param>
+    ''' <returns></returns>
+    Private Function OpenSQLConnection(Connection As OracleConnection) As OracleConnection
+        If Connection.State = ConnectionState.Closed Then
+            Connection.Open()
+        End If
+
+        Return Connection
+    End Function
+
+    <DebuggerStepThrough()>
+    Private Function MaskConnectionString(ConnectionString As String) As String
+        Try
+            If ConnectionString Is Nothing OrElse ConnectionString.Length = 0 Then
+                Throw New ArgumentNullException("ConnectionString")
+            End If
+
+            Dim oBuilder As New OracleConnectionStringBuilder() With {.ConnectionString = ConnectionString}
+            Dim oConnectionString = ConnectionString.Replace(oBuilder.Password, "XXXXX")
+            Return oConnectionString
+        Catch ex As Exception
+            _Logger.Error(ex)
+            Return "Invalid ConnectionString"
+        End Try
+    End Function
+End Class